Update...Well, everything went quite well. Completed migration of one server in about 2 hours.
Here is what was used to complete the task.
Share out the User folders on each volume
code:
@ECHO OFF
REM Filename FP03SHARES.BAT
REM Last modified by NTDOC on July 18, 2001 - Idea by Kyder
CLS
ECHO.
ECHO This batch file will share all folders as a hidden share using
ECHO the name of the folder as input. It must be run from the same
ECHO server it will be changing the shares on.
ECHO.
ECHO Press CTRL-C now to quit this batch file.
ECHO Otherwise press any key to continue...
PAUSE >nul
for /f "Tokens=*" %%i in ('dir /B D:\users') do NET SHARE %%i$=D:\users\%%i /Y
for /f "Tokens=*" %%i in ('dir /B E:\users') do NET SHARE %%i$=E:\users\%%i /Y
Change Rights on User Folders
code:
@ECHO OFF
REM Filename FP03RIGHTS.BAT
REM Created and Last modified by NTDOC on July 18, 2001
CLS
ECHO This batch file can be run from any Workstation with XCALCS on it
ECHO.
ECHO This batch file will reset ALL the file and folder permissions on
ECHO the SAN Server (SM-CAG-FP03 VOL1\USERS and VOL2\USERS)
ECHO It will remove all current permissions and set the following permissions
ECHO (Domain Admins-Full, Administrators-Full, SYSTEM-Full, and USER-Change)
ECHO.
ECHO WARNING - WARNING This is an irreversible action.
ECHO.
ECHO It may take half an hour or more to complete.
ECHO Please contact ???? for any questions.
ECHO.
ECHO Press CTRL-C now to quit this batch file.
ECHO Otherwise press any key to continue...
PAUSE >nul
for /f "Tokens=*" %%i in ('dir /B \\sm-cag-fp03\VOL1\users') do xcacls \\sm-cag-fp03\VOL1\users\%%i /T /Y /P "WDI\DOMAIN ADMINS":F;F Administrators:F;F SYSTEM:F;F WDI\%%i:C;C
for /f "Tokens=*" %%i in ('dir /B \\sm-cag-fp03\VOL2\users') do xcacls \\sm-cag-fp03\VOL2\users\%%i /T /Y /P "WDI\DOMAIN ADMINS":F;F Administrators:F;F SYSTEM:F;F WDI\%%i:C;C
Change Home Directory in User Manager
code:
@ECHO OFF
REM File name CHANGEHOMEDIR.BAT
REM Last modified by NTDOC - on July 18, 2001
CLS
ECHO This batch file is used to change the Home Directory
ECHO for all users on SM-CAG-FP03 VOL1 and VOL2
ECHO You must run this batch file from a BDC to update
ECHO the User Manager settings.
ECHO.
ECHO Please contact ???? if you have any questions
ECHO Last updated: July 18, 2001
ECHO.
ECHO Press CTRL-C now to quit this batch file.
ECHO Otherwise press any key to continue...
PAUSE >nul
for /f "Tokens=*" %%i in ('dir /B \\sm-cag-fp03\vol1\users') do NET USER %%i /homedir:\\sm-cag-fp03\%%i$
for /f "Tokens=*" %%i in ('dir /B \\sm-cag-fp03\vol2\users') do NET USER %%i /homedir:\\sm-cag-fp03\%%i$
We changed all the rights on the user directories because they were all in a mess from years of invalid permissions carried over from our days of Novell.
Now I need to work on a KiXtart script that will create a new user, add them to the Domain, create their folder, share their folder, then give them rights. Would also like to come up with a way of doing above when we migrate other user folders onto this SAN, but ignore folders that are already there. Ideas anyone? Maybe read a list then feed it back somehow?
Thanks again to all for ideas on this post and others out there that helped me to get this done.
[ 25 July 2001: Message edited by: NTDOC ]
