:SetLegalMessage

    ; The corporate Legal Message is written to the registry. The local LAN Admins can submit

    ; language specific text which will be used automatically.

    ;

    ; The language specific text must have the following format. Us notepad.exe to create a text

    ; file. The first line will contain the text used in caption of the dialog box. The second

    ; line will be the entire legal message text. The ENTER key should be pressed after the second line.



    If $RAS=0 and not ProductSuite("Terminal Server") ;and $VPN

        Dim $String1, $String2

        Dim $RC1, $RC2

        Dim $RegKey

        Dim $Autologon

        Dim $Lang, $file



        $Lang = GetUserLanguageCode()

        $file = $Lpath + "\corp\legalmsg\$Lang.txt"



        if OpenFile(2, $file, 2) <> 0

            Writelog("Native language legal message not found: $file")

            ;$ErrorState set to 1 in OpenFile. Reset $ErrorState to 0 as not to display the error notification.

            $ErrorState = 0

            $file = $Lpath + "\corp\legalmsg\0409.txt"



            if OpenFile(2, $file, 2) <> 0

                Writelog("Error: Legal text not found. " + $file)

            endif

        endif



        $String1 = Readline(2)

        $String2 = Readline(2)

        $RC1 = close(2)



        Select

            Case $OS="WinNT"

                $RegKey="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\winlogon"

            Case $OS="Win9x"

                $RegKey="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\winlogon"

        EndSelect



        ; The legal message interferes with the autologon process and therefore will not be installed

        ; on computers configured for autologon.



        $Autologon=ReadValue("$RegKey","AutoAdminLogon")

        if @error = 2

            $Autologon=0

        endif

        If $Autologon=0

            $RC1=WriteValue($RegKey,"LegalNoticeCaption",$String1,"REG_SZ")

            $RC2=WriteValue($RegKey,"LegalNoticeText",$String2,"REG_SZ")

            if $RC1=0 and $RC2=0

                WriteLog ("Wrote legal message to registry.")

            else

                WriteLog ("Error writing Legal Message: LegalNoticeCaption error=$RC1, LegalNoticeText error=$RC2")

                if $RC1<>5

                    $ErrorState=1

                endif

            endif

        Else

            WriteLog ("Legal Message skipped because computer is configured for AutoLogon.")

        Endif



        If $OS="WinNT"

            $RC=WriteValue($RegKey,"RunLogonScriptSync","1","REG_DWORD")

        Endif

    Endif

    Return