code:

---

@ECHO OFF
CLS

ECHO Verifying / Updating Login Script

REM set KiXtart version
SET KIXVER=KIXTART.412

REM detect the operating system and go to the appropriate segment

VER | find "2000" > nul 
IF not errorlevel 1 GOTO Win_2K 

VER | find "NT" > nul 
IF not errorlevel 1 GOTO Win_NT 

VER | find "XP" > nul 
IF not errorlevel 1 GOTO Win_XP

VER | find "98" > nul 
IF not errorlevel 1 GOTO Win_98

VER | find "95" > nul 
IF not errorlevel 1 GOTO Win_95

VER | find "Millennium" > nul
IF not errorlevel 1 GOTO WIN_ME

GOTO DOS

REM client is running DOS
:DOS
ECHO.
ECHO No Login Script Available For DOS Clients
ECHO.
GOTO End

REM client is running Windows 9x
:Win_95
:Win_98
:Win_ME
ECHO.
ECHO Checking KiXtart files for Windows 95/98/ME
ECHO.
REM the DEL command removes any KiXtart file from the %WINDIR%\SYSTEM directory

%WINDIR%\COMMAND\XCOPY %0\..\KIX32.EXE %WINDIR%\ /D /H /I /R /V /C >NUL
%WINDIR%\COMMAND\XCOPY %0\..\WKIX32.EXE %WINDIR%\ /D /H /I /R /V /C >NUL
%WINDIR%\COMMAND\XCOPY %0\..\KX*.DLL %WINDIR%\ /D /H /I /R /V /C  >NUL
%WINDIR%\COMMAND\XCOPY %0\..\%KIXVER% %WINDIR%\ /D /H /I /R /V /C  >NUL

GOTO Run9xScript

REM client is running Windows NT/2000/XP
:Win_NT
:Win_2K
:Win_XP
ECHO.
ECHO Checking KiXtart files for Windows NT/2000/XP
ECHO.
REM the DEL command removes any KiXtart file from the %WINDIR%\SYSTEM32 directory

ECHO y| XCOPY %LOGONSERVER%\NETLOGON\KIX32.EXE %WINDIR%\ /D /H /I /R /V /C >NUL >NUL
ECHO y| XCOPY %LOGONSERVER%\NETLOGON\WKIX32.EXE %WINDIR%\ /D /H /I /R /V /C >NUL >NUL
ECHO y| XCOPY %LOGONSERVER%\NETLOGON\%KIXVER% %WINDIR%\ /D /H /I /R /V /C >NUL >NUL

GOTO RunScript

REM run the logon script for Windows NT/2000/XP
:RunScript
ECHO Loading Logon Script for Windows NT/2000/XP, Please Wait...
ECHO.

REM check whether Kixtart is installed locally
IF EXIST %WINDIR%\%KIXVER% GOTO LocalExe
IF EXIST %LOGONSERVER%\NETLOGON\%KIXVER% GOTO RemoteExe
GOTO KiXtartError

REM Kixtart is installed locally
:LocalExe
%WINDIR%\KIX32.EXE %LOGONSERVER%\NETLOGON\LOGIN.KIX
GOTO End

REM Kixtart is not installed locally
:RemoteExe
%LOGONSERVER%\NETLOGON\KIX32.EXE %LOGONSERVER%\NETLOGON\LOGIN.KIX
GOTO End

REM run the logon script for Windows 95/98/ME
:Run9xScript
ECHO Loading Logon Script for Windows 95/98/ME, Please Wait...
ECHO.

REM check whether Kixtart is installed locally
IF EXIST %WINDIR%\%KIXVER% GOTO 9xLocalExe
IF EXIST %0\..\%KIXVER% GOTO 9xRemoteExe
GOTO KiXtartError

REM Kixtart is installed locally
:9xLocalExe
%WINDIR%\KIX32.EXE %0\..\LOGIN.KIX
GOTO End

REM Kixtart is not installed locally
:9xRemoteExe
%0\..\KIX32.EXE %0\..\LOGIN.KIX
GOTO End

:KiXtartError
REM Display an error message and notify the Systems Administrator since the user won't be doing it anyway
ECHO.
ECHO Error loading the NMRC-NT logon script
ECHO.
ECHO Please notify the Systems Administrator!
ECHO.
NET SEND REDPOINT "Error loading the NMRC-NT logon script for user "%USERNAME%" on computer "%COMPUTERNAME% >NUL >NUL
PAUSE
GOTO End

:End
REM remove KiXtart version
SET KIXVER=

ECHO.
ECHO.
ECHO Finishing Login...

@ECHO OFF
CLS
EXIT 0

---