hey guys.

I tested GUIPassPrompt with kix4.10 and 4.11 beta 2. Both test using the code found here GUIPassPrompt were ok.
(ok this version is not the same version here.... sorry)

Austin,

I found the bug in this version of GUIPassPrompt

code:
function GUIPassPrompt($case, $force, optional $title)
	;This is a GUI password Prompt.
	; Syntax:
	;	GUIPassPrompt(Case Sensetive[0/1] | force[0/1] | Optional Title )
	;	Case Sensetive  [0,1]
	;		0 = ignore case
	;		1 = all password are case sensitive
	;
	;	Force	[0,1]
	;		"0" will not force a password		
	;		"1" will force the user to enter a password
	;
	;	Title(optional)  "Your title here"
	;		Defalut title = "Please enter your password."
	;		set this option to change it.
	;
	;Example:
	;	;This will show a non case sensetive password prompt with the default title and not forced
	;	$password = GUIpassprompt(0,0)
	;
	;	;this is a forced case sensetive password prompt with the title "Enter your password"
	;	$password = GUIPassPrompt(1,1,"Enter your password")

	DIM $title, $case, $top, $left, $height, $Width, $False, $true
	DIM $status, $Password1, $password2, $doc, $nul, $html
	global $GUIPassPromptOld

	$password = ""
	$top      = "100"
	$left     = "200"
	$height   = "180"
	$width    = "275"
	$false    = 0
	$true     = -1
	If $title = ""
		$title = "SQL PASSWORD UTLILTY"
	endif

	$html = '
	<html><head>
	<title>$title</title>
	
	<style>
	<!---body{ background-color: silver; color: black;font-family: tahoma, arial; font-size: 
	10pt; margin: 3px "input.tbox { border: lpx black solid;}td { font: 10pt tahoma; }--->
	</style></head>
	
	<body scroll=no onresize="window.resizeto(240,120);">
	
	<table align=center>
	 <form name=frm>
	   <tr>
	     <td align=right>Current: </td>
	     <td colspan=2><input id=password0 type=password value="" class=tbox></td>
	   </tr>
	   <tr>
	     <td align=right>Password: </td>
	     <td colspan=2><input id=password1 type=password value="" class=tbox></td>
	   </tr>
	   <tr>
	     <td align=right>Confirm: </td>
	     <td colspan=2><input id=password2 type=password value="" class=tbox></td>
	   </tr>
	   <tr>
	     <td><input id=reset type=button value=" Submit " onclick="frm.status.value=1"><input type=hidden id=status name=status value=0></td>
	     <td align=right><input id=close type=button value=" Cancel " onclick="frm.status.value=2"></td>
	   </tr>
	 </form>
	</table></body></html>'

	:Closed_Window
	$ie = CreateObject("internetexplorer.application")
	; Set properties and display form ...
	$ie.addressbar = $false
	$ie.menubar = $false
	$ie.toolbar = $false
	$ie.statusbar = $false
	$ie.resizable = $false
	$ie.top = $top
	$ie.left = $left
	$ie.height = $height
	$ie.width = $width
	$ie.visible = $true

	$ie.navigate("about:blank")

	while $ie.busy <>0 and @error = 0 loop

	; Get a handle to the open document ...
	$doc = $ie.document
	$doc.write($html)
	while setfocus("$title") <> 0 loop

	$status = $doc.GetElementById("status")
	$password0 = $doc.GetElementById("password0")
	$password1 = $doc.GetElementById("password1")
	$password2 = $doc.GetElementById("password2")

	while @error = 0 and $status.value <> ""
		select
			case $status.value = "1"
				;submit was clicked
				Select
					case $password1.value <> $password2.value
						$nul = Messagebox("Passwords do not match", "ERROR",4144)
						$password0.value = ""
						$password1.value = ""
						$password2.value = ""
					case $password1.value = "" or $password2.value = ""
						$nul = Messagebox("Blank passwords are not allowed", "ERROR",4144)
						$password0.value = ""
						$password1.value = ""
						$password2.value = ""
					case $case = 1
						if $password1.value == $password2.value
							$GUIPassPrompt = $password1.value
							$GUIPassPromptOld = $password0.value
							$ie.quit()
							exit
						else
							$nul = Messagebox("Passwords do not match", "ERROR",4144)
							$password0.value = ""
							$password1.value = ""
							$password2.value = ""
						endif
					case $case = 0
						if $password1.value = $password2.value
							$GUIPassPrompt = lcase($password1.value)
							$GUIPassPromptOld = $password0.value
							$ie.quit()
							exit
						else
							$nul = Messagebox("Passwords do not match", "ERROR",4144)
							$password0.value = ""
							$password1.value = ""
							$password2.value = ""
						endif

				endselect

				$status.value = 0
			case $status.value = "2"
				;cancel was clicked
				if $force = "1"
					$nul = Messagebox("You Must Change your password!", "ERROR",4144)
				else	
					$ie.quit()
					exit(1067)
				endif
				$status.value = 0
		endselect
	loop
	if $force = "1"
		$nul = Messagebox("You Must Change your password!", "ERROR",4144)
		goto Closed_Window
	else	
		$ie.quit()
		exit
	endif

endfunction