First off.. let's run the following script. Open and run from a command prompt - kix32 userdn.kix. Then copy the resulting DN string from the screen & post it back here. We need to see if you're defining the OU offset properly.

Next, the MAILSIG.INI is an example - you need to customize it based on the OU or Department - OR - simply define the COMMON section properly if everyone is to get the same signature. SPACER.GIF is a 1x1 pixel transparent image, probably not what you want. Put your company logo into the folder and define the name in the COMMON section's IMAGE value. If you don't use an image, leave it the way you have it.

Finally, run the script from a command prompt - NOT by double-clicking or drag & drop methods. These will prevent you from seeing the diagnostic or error messages! Then, after running the CreateMailSig script (from a command prompt), CD to %APPDATA%\Microsoft\Signatures and verify that the signature files have been created there.

Oh, and since the signature file is created in HTML, go into the Outlook properties and make sure that the default message format is HTML and not RTF or TEXT.

Glenn 


;; KixGenerated: 2009/05/03 22:19:03 
Break On
Dim $
 
$ = SetOption('WrapAtEOL', 'On')
 
'   User: ' @USERID ?
'User DN: ' ADSIUserInfo() ? ?
'Press any key to exit: '
Get $
 
;; 
;;====================================================================== 
;; 
;;FUNCTION       ADSIUserInfo() 
;; 
;;ACTION         Get or Set a user attribute via ADSI 
;; 
;;AUTHOR         Glenn Barnas 
;; 
;;VERSION        1.1 / 2008/08/20 - Modified to return current UserDN when no args are specified 
;;               1.0 / 2008/03/05 
;; 
;;SYNTAX         ADSIUserInfo(User, Attribute [, Value]) 
;; 
;;PARAMETERS     User - 	OPTIONAL, AD Distinguished name. Defaults to current user 
;; 
;;               Attribute - 	OPTIONAL, Attribute value to read or set. If User and Attribute are both null, 
;;                                        the current user's DN will be returned. If User is specified and  
;;                                        Attribute is null, and error is returned 
;; 
;;               Value - 	OPTIONAL, Value to set 
;; 
;;REMARKS        Returns AD attribute value (including what was just set) 
;;               Sets an AD attribute value 
;; 
;;RETURNS        String - value of defined attribute or UserDN if no args are specified 
;; 
;;DEPENDENCIES   none 
;; 
;;TESTED WITH    W2K, WXP, W2K3, Vista 
;; 
;;EXAMPLES        
; 
Function ADSIUserInfo(OPTIONAL $_User, OPTIONAL $_Attr, OPTIONAL $_Value)
 
  Dim $_			; temporary var 
  Dim $_D			; "$" character 
  Dim $_oUser			; User object pointer 
  Dim $_Cmd			; execute command string 
  Dim $_RtnVal			; data returned from Execute 
  Dim $_objSysInfo 		; object pointer 
 
  $_D = Chr(36)
 
  ; Determine user DN if not supplied 
  If Not $_User
    $_objSysInfo = CreateObject("ADSystemInfo")
    $_User = $_objSysInfo.UserName
    $_ = 1
    If @ERROR Exit @ERROR EndIf
    ; Return the DN if no attribute was specified 
    If Not $_Attr
      $ADSIUserInfo = $_User
      Exit 0
    EndIf
  EndIf
 
  ; Exit with error if Attribute is null 
  If Not $_Attr
    Exit 87
  EndIf
 
  ; Get the user pointer 
  $_oUser = GetObject('LDAP://' + $_User)
  If @ERROR Exit @ERROR EndIf			; exit if error creating object 
 
  ; write the value if supplied 
  If $_Value
    $_Cmd = $_D + '_oUser.put("' + $_Attr + '", "' + $_Value + '")'
    $_ = Execute($_Cmd)
    $_oUser.SetInfo
    If @ERROR
      Exit @ERROR
    EndIf
  EndIf
 
  ; read and return the current value 
  $_Cmd = $_D + '_RtnVal = ' + $_D + '_oUser.' + $_Attr
  $_ = Execute($_Cmd)
  $ADSIUserInfo = $_RtnVal
 
  Exit @ERROR
 
EndFunction
_________________________
Actually I am a Rocket Scientist! \:D