This might be promising.

http://www.dimastr.com/redemption/profiles.htm

 Quote:

....
Normally MAPI profiles can only be manipulated using Extended MAPI in C/C++/Delphi. Profman library allows to manipulate MAPI profiles from any language, including VB and VB script.
....


This is the code from example 6. Looks like VBS but I'm not sure because I'm almost blind in the VB(S) world.
 Code:
add an extra Exchange mailbox to a given profile. This sample uses CDO to retrieve the properties of the mailbox to be added
'see Q171636 for details

'todo: replace the name of the profile!!!
strProfileName = "Dmitry Streblechenko"

PR_STORE_PROVIDERS = &H3D000102
PR_PROVIDER_UID = &H300C0102
PR_DISPLAY_NAME = &H3001001E
PR_PROFILE_MAILBOX = &H660B001E
PR_PROFILE_SERVER = &H660C001E
PR_PROFILE_SERVER_DN = &H6614001E
PR_EMAIL_ADDRESS = &H3003001E

Sub AddMailBox(strProfile, strDisplayName, strMailboxDN, strServer, strServerDN)
  set Profiles=CreateObject("ProfMan.Profiles")
  if strProfile = "" Then
    set Profile = Profiles.DefaultProfile
  Else
    set Profile = Profiles.Item(strProfile)
   End If
  'find the Exchange service
  set Services = Profile.Services
  for i = 1 to Services.Count
    set Service = Services.Item(i)
    if Service.ServiceName = "MSEMS" Then
      'Add "EMSDelegate" provider
      set Properties = CreateObject("ProfMan.PropertyBag")
      Properties.Add PR_DISPLAY_NAME, strDisplayName
      Properties.Add PR_PROFILE_MAILBOX, strMailboxDN
      Properties.Add PR_PROFILE_SERVER, strServer
      Properties.Add PR_PROFILE_SERVER_DN, strServerDN
      set Provider = Service.Providers.Add("EMSDelegate", Properties)
      'update the old value of PR_STORE_PROVIDERS so that Outlook
      'will show the mailbox in the list in Tools | Services
      set GlobalProfSect = Profile.GlobalProfSect
      OldProviders = GlobalProfSect.Item(PR_STORE_PROVIDERS)
      strUID = Provider.UID
      GlobalProfSect.Item(PR_STORE_PROVIDERS) = OldProviders & strUID
    End If
  Next
End Sub

'get PR_PROFILE_SERVER and PR_PROFILE_SERVER_DN 
'It is assumed that the mailbox to add is on the same server as the current user's mailbox 
MAPI_STORE_PROVIDER = 33
set Profiles=CreateObject("ProfMan.Profiles")
set Profile = Profiles.Item(strProfileName)
set Services = Profile.Services
for i = 1 to Services.Count
  set Service = Services.Item(i)
  if Service.ServiceName = "MSEMS" Then
    set Providers = Service.Providers
    for j = 1 to Providers.Count
      set Provider = Providers.Item(j)
      if Provider.ResourceType = MAPI_STORE_PROVIDER Then
        set ProfSect = Provider.ProfSect
        strProfileServer = ProfSect.Item(PR_PROFILE_SERVER)
        strProfileServerDN = ProfSect.Item(PR_PROFILE_SERVER_DN)
      End If
    Next
  End If
Next

'Add the first GAL entry's mailbox to the default profile
set AddrEntry = CDOSession.AddressLists.Item("Global Address List").AddressEntries.Item(1)
AddMailBox strProfileName, _
                    "Mailbox - " & AddrEntry.Fields(PR_DISPLAY_NAME).Value, _
                    AddrEntry.Fields(PR_EMAIL_ADDRESS).Value, _
                    strProfileServer, _
                    strProfileServerDN
_________________________
Mart

- Chuck Norris once sold ebay to ebay on ebay.