Break On
Dim $SO
$SO=SetOption('Explicit','On')
$SO=SetOption('NoVarsInStrings','On')
$SO=SetOption('NoMacrosInStrings','On')
 
Dim $MyBIOSInfo,$Q
Global $Make,$Model,$SerNumb,$HKLMSMWCVAP,$Explorer,$Msg
$HKLMSMWCVAP = 'HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths'
$Explorer    = ReadValue($HKLMSMWCVAP + '\IEXPLORE.EXE','')
$MyBIOSInfo=GetBIOSInfo()
$Make = $MyBIOSInfo[0]
$Model = $MyBIOSInfo[1]
$SerNumb = $MyBIOSInfo[2]
 
$Msg=MessageBox('MFG  :  ' + $Make +@CRLF + 'Model:  ' + $Model + @CRLF + 'Serial :  ' + $SerNumb + @CRLF+@CRLF+
 'Go to the Web Support site for drivers ? ','Computer Model',4385)
If 1=$Msg
  GoToMake()
EndIf
Exit 1
 
Function GetBIOSInfo()
  Dim $WMIService, $Mfg,$Model,$Ser
  Dim $MItem,$SItem, $SerialNumber, $Manufacturer
  $WMIService = GetObject("winmgmts:" + "\root\cimv2")
  $Mfg  = $WMIService.ExecQuery("Select * from Win32_ComputerSystem",,48)
  $Ser  = $WMIService.ExecQuery("Select * from Win32_BIOS",,48)
  For Each $MItem In $Mfg
    If $MItem
      $Manufacturer = Trim($MItem.Manufacturer)
      $Model = Trim($MItem.Model)
    EndIf
  Next
  For Each $SItem In $Ser
    If $SItem
      $SerialNumber = Trim($SItem.SerialNumber)
    EndIf
  Next
  $GetBIOSInfo=$Manufacturer,$Model,$SerialNumber
EndFunction
 
Function GoToMake()
  Dim $URL
  Select
    Case InStr($Make,'dell') $URL = "http://support.dell.com/support/downloads/index.aspx?ServiceTag="+$SerNumb
    Case 1 $URL = ''
  EndSelect
    If $URL
      RUN $Explorer + ' ' + $URL
    Else
      $Msg=MessageBox('Unable to determine computer model.','Model unknown',48)
    EndIf
EndFunction
 

Break On
Dim $SO
$SO=SetOption('Explicit','On')
$SO=SetOption('NoVarsInStrings','On')
$SO=SetOption('NoMacrosInStrings','On')
 
Dim $Chk, $MyBIOSInfo
Dim $Mfg, $Model, $Ser, $Esc
$Chk = WMIConfirm('computer name')
If $Chk
  $MyBIOSInfo = GetBIOSInfo()
  If VarType($MyBIOSInfo) >8
    $Mfg	= $MyBIOSInfo[0]
    'Mfg: ' + $Mfg ?
    $Model	= $MyBIOSInfo[1]
    'Model: ' + $Model ?
    $Ser	= $MyBIOSInfo[2]
    'Serial / Tag number: ' + $Ser ?
    $Esc	= BaseConverter($Ser,36,10)
    'Express Service Code: ' + $Esc ?
  Else
    'Error getting BIOS information. ' + @ERROR + ' - ' + @SERROR ?
  EndIf
Else
  'Error accessing WMI. ' + @ERROR + ' - ' + @SERROR ?
EndIf
 
Function WMIConfirm(optional $sComputer) 
  Dim $objWMIService, $objWMISetting, $colWMISettings 
  $sComputer = IIf(Not $sComputer,'','\\'+Join(Split($sComputer,'\'),'',3)+'\') 
  $objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!"+$sComputer+'root\cimv2') 
  ; Failed - return 0 and exit with error value  
  If @ERROR 
    $WMIConfirm = 0 
    Exit Val('&' + Right(DecToHex(@ERROR), 4)) 
  EndIf 
  $colWMISettings = $objWMIService.ExecQuery("Select * from Win32_WMISetting") 
  For Each $objWMISetting In $colWMISettings 
    $WMIConfirm = $objWMISetting.BuildVersion 
  Next 
  Exit 0 
EndFunction
 
Function GetBIOSInfo(optional $sComputer)
  Dim $objWMIService, $Mfg,$Model,$Ser
  Dim $M,$S, $SerialNumber, $Manufacturer
  $objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!"+$sComputer+'root\cimv2')
  If @ERROR 
    $GetBIOSInfo = 0 
    Exit Val('&' + Right(DecToHex(@ERROR), 4)) 
  EndIf 
  $Mfg  = $objWMIService.ExecQuery("Select * from Win32_ComputerSystem",,48)
  $Ser  = $objWMIService.ExecQuery("Select * from Win32_BIOS",,48)
  For Each $M In $Mfg
    If $M
      $Manufacturer = Trim($M.Manufacturer)
      $Model = Trim($M.Model)
    EndIf
  Next
  For Each $S In $Ser
    If $S
      $SerialNumber = Trim($S.SerialNumber)
    EndIf
  Next
  $GetBIOSInfo=$Manufacturer,$Model,$SerialNumber
  Exit 0
EndFunction
 
Function BaseConverter($v,$f,$t)
 dim $,$e,$y,$n,$x,$z
   $=0
   $t=$+$t
   $f=$+$f
   $e=($f>36)|($t>36)|($f<2)|($t<2)   
   $y=1.
   for $n=len($v) to 1 step -1
      $x=ASC(UCASE(substr($v,$n,1)))
      $z=($x-48-($x>64)*7)
      IF ($z<0)|(($x>57)&($x<65))|$e|($z>($f-1))
       EXIT 1
      ENDIF
      $=$y*$z+$
      $y=$y*$f
   next
   $n=""
   While $
      $x=INT($-(INT($/$t)*$t))
      $=($-$x)/$t
      $n=CHR($x+48+($x>9)*7)+$n
   Loop
   $BaseConverter=$n
Endfunction