Try clearing your cache, try a different browser.

Try running this script on your system but MAKE SURE you have KiXtart 4.52 Beta 2 as it WILL NOT work correctly with any earlier version.

WARNING If you do run this script it will remove all Internet Explorer cache,cookies, history for every profile on the system as well as Java cached files and all %temp% files.
 
 
Code:

Break On
Dim $SO
$SO=SetOption('Explicit','On')
$SO=SetOption('NoVarsInStrings','On')
$SO=SetOption('NoMacrosInStrings','On')
 
ClearTemporary()
 
Function ClearTemporary()
  Dim $ProL,$PL,$Tmp,$DV
  $ProL = ExpandEnvironmentVars(ReadValue('HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList','ProfilesDirectory'))
  $PL   = Dir($ProL)
  $DV   = DelKey('HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{5E6AB780-7743-11CF-A12B-00AA004AE837}\Count')
  $DV   = DelKey('HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count')
  While $PL <>''
    If $PL
      If Not InStr($PL,'.') And Not InStr($PL,'..')
        If Exist($ProL+'\'+$PL+'\Local Settings\Temporary Internet Files\Content.IE5\index.dat')
          RD $ProL+'\'+$PL+'\Local Settings\Temporary Internet Files\Content.IE5\' /S
          If @ERROR DEL $ProL+'\'+$PL+'\Local Settings\Temporary Internet Files\Content.IE5\index.dat' /P EndIf
          MD $ProL+'\'+$PL+'\Local Settings\Temporary Internet Files\Content.IE5'
        EndIf
        If Exist($ProL+'\'+$PL+'\Cookies\index.dat')
          RD $ProL+'\'+$PL+'\Cookies\' /S
          If @ERROR DEL $ProL+'\'+$PL+'\Cookies\index.dat' /P EndIf
          MD $ProL+'\'+$PL+'\Cookies\'
        EndIf
        If Exist($ProL+'\'+$PL+'\Local Settings\History\History.IE5\index.dat')
          RD $ProL+'\'+$PL+'\Local Settings\History\History.IE5\' /S
          If @ERROR DEL $ProL+'\'+$PL+'\Local Settings\History\History.IE5\index.dat' /P EndIf
          MD $ProL+'\'+$PL+'\Local Settings\History\History.IE5\'
        EndIf
        If Exist($ProL+'\'+$PL+'\Local Settings\Temp')
          RD $ProL+'\'+$PL+'\Local Settings\TEMP\' /S
          MD $ProL+'\'+$PL+'\Local Settings\TEMP'
        EndIf
        If Exist($ProL+'\'+$PL+'\Application Data\Sun\Java\Deployment\cache\')
          RD $ProL+'\'+$PL+'\Application Data\Sun\Java\Deployment\cache\' /S
          MD $ProL+'\'+$PL+'\Application Data\Sun\Java\Deployment\cache'
        EndIf
        If Exist($ProL+'\'+$PL+'\.jpi_cache\')
          RD $ProL+'\'+$PL+'\.jpi_cache\' /S
          MD $ProL+'\'+$PL+'\.jpi_cache'
        EndIf
      EndIf
    EndIf
    $PL = Dir()
  Loop
  If Exist('%windir%\system32\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\index.dat')
    RD '%windir%\system32\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\' /S
    If @ERROR DEL '%windir%\system32\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\index.dat' /P EndIf
    MD '%windir%\system32\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\'
  EndIf
  If Exist('%windir%\system\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\index.dat')
    RD '%windir%\system\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\' /S
    If @ERROR DEL '%windir%\system\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\index.dat' /P EndIf
    MD '%windir%\system\config\systemprofile\Local Settings\Temporary Internet Files\Content.IE5\'
  EndIf
  If Exist('%windir%\Application Data\Sun\Java\Deployment\cache\')
    RD '%windir%\Application Data\Sun\Java\Deployment\cache\' /S
    MD '%windir%\Application Data\Sun\Java\Deployment\cache'
  EndIf
  If Exist('%windir%\Temporary Internet Files\Content.IE5\index.dat')
    If @INWIN=2
      Dim $RC
      RD '%windir%\Temporary Internet Files\Content.IE5\' /S
      $RC=WriteProfileString ('%windir%\Wininit.ini','rename','NUL','%windir%'+'\TEMPOR~1\CONTENT.IE5\INDEX.DAT')
    Else
      RD '%windir%\Temporary Internet Files\Content.IE5\' /S
      If @ERROR DEL '%windir%\Temporary Internet Files\Content.IE5\index.dat' /P EndIf
      MD '%windir%\Temporary Internet Files\Content.IE5'
    EndIf
  EndIf
  $Tmp = '%temp%'
  If Exist($Tmp)
    If Len($Tmp) >4
      RD $Tmp+'\' /s
      MD $Tmp
    EndIf
  EndIf
  Exit @ERROR
EndFunction