'Server: ' 
gets $server
$admins = getobject('WinNT://' + $server + '/Administrators')
for each $member in $admins.Members
	? $member.Name
next

break on
$ = setoption('Explicit', 'On')

dim $inFile, $outFile, $curServer
dim $admins,$member,$

; list of servers
$inFile = 'c:\Servers.txt'

; results
$outFile = 'c:\ServerAdmins.txt'

$ = open(1,$inFile)
if exist($outFile)
   del $outFile
endif
$ = redirectoutput($outFile)

$curServer = trim(readline(1))
while @error = 0
   ucase($curServer) ':'
   if cstr(wmiPing($curServer))
      $admins = getobject('WinNT://' + $curServer + '/Administrators')
      if @error = 0
         for each $member in $admins.Members
            ? $member.Name
         next
      else
         ? 'Error: ' @serror
      endif
   else
      ? 'Warning: Does not ping'
   endif
   ? ?
   $curServer = trim(readline(1))

loop

Function wmiPing($Address,Optional $Timeout,Optional $BlockSize)
   Dim $Query,$oWMI,$oItem,$cItems

   $Query = "Select ResponseTime,StatusCode From Win32_PingStatus Where Address='" + $Address + "'"
   If $Timeout
      $Query = $Query + " And TimeOut=" + $Timeout
   EndIf
   If $BlockSize
      $Query = $Query + " And BufferSize=" + $BlockSize
   EndIf
   $oWMI = GetObject("winmgmts:root\cimv2")
   $cItems = $oWMI.ExecQuery($Query)
   For Each $oItem In $cItems
      If (VarTypeName($oItem.StatusCode) = 'Null') Or $oItem.StatusCode
         Exit 1
      Else
         $wmiPing = $oItem.ResponseTime
      EndIf
   Next
EndFunction

Quote:

---

NTDOC,

Of course will do , I've just entered Kix World .And much intrested after see sample scripts .But for time being programming/scripting too far for me to acheive .Thats Why I asked you to the group .To do it myself will take days and days to understand ..But need to have it as quick as possible , thats also another reason why I looked that forum .


Thank you very much indeed .

Rgds

---

We all needed to learn to walk before trying to run

It's much better if you also understand what the script does and not just use it. Problems will come sooner or later and then you can't fix them that’s why it's better to learn kix before using kix.

break on
$ = setoption('Explicit', 'On')

dim $inFile, $outFile, $curServer
dim $admins,$member,$adsPath,$

; list of servers
$inFile = 'c:\Servers.txt'

; results
$outFile = 'c:\ServerAdmins.txt'

$ = open(1,$inFile)
if exist($outFile)
   del $outFile
endif
$ = redirectoutput($outFile)

$curServer = trim(readline(1))
while @error = 0
   ucase($curServer) ':'
   if cstr(wmiPing($curServer))
      $admins = getobject('WinNT://' + $curServer + '/Administrators')
      if @error = 0
         for each $member in $admins.Members
            $adsPath = $member.adsPath
            $adsPath = split($adspath,'WinNT://')[1]
            if instr($adsPath, $curServer)
               $adsPath = substr($adsPath,instr($adsPath,'/') + 1)
            endif
            ? $adsPath
         next
      else
         ? 'Error: ' @serror
      endif
   else
      ? 'Warning: Does not ping'
   endif
   ? ?
   $curServer = trim(readline(1))

loop

Function wmiPing($Address,Optional $Timeout,Optional $BlockSize)
   Dim $Query,$oWMI,$oItem,$cItems

   $Query = "Select ResponseTime,StatusCode From Win32_PingStatus Where Address='" + $Address + "'"
   If $Timeout
      $Query = $Query + " And TimeOut=" + $Timeout
   EndIf
   If $BlockSize
      $Query = $Query + " And BufferSize=" + $BlockSize
   EndIf
   $oWMI = GetObject("winmgmts:root\cimv2")
   $cItems = $oWMI.ExecQuery($Query)
   For Each $oItem In $cItems
      If (VarTypeName($oItem.StatusCode) = 'Null') Or $oItem.StatusCode
         Exit 1
      Else
         $wmiPing = $oItem.ResponseTime
      EndIf
   Next
EndFunction