You are not logged in. [Log In] KiXtart.org website » Forums » KiXtart » COM Scripting » Active Directory Attribute Browser - Browse your schema for AD attributes
Register User       Forum List       Calendar       FAQ
Page 1 of 1 1
Topic Options
#146768 - 2005-08-29 09:34 PM Active Directory Attribute Browser - Browse your schema for AD attributes
Chris S. Offline
MM club member
*****

Registered: 2002-03-18
Posts: 2368
Loc: Earth
I built this little browser to enumerate through the attributes available to the classes in your schema. This lists the attributes, syntax, value type (single vs. multi), and whether the attribute is mandatory vs. optional.



Code:

Break On
 
$=SetOption("Explicit","On")
 
Global $System,$Form,$MessageBox1,$ImageList1
 
;region === KiXforms Region =============================================== 
 
$System = CreateObject("Kixtart.System")
 
;region === MessageBox ==================================================== 
$MessageBox1 = $System.MessageBox()
$MessageBox1.Title = "Information..."
$MessageBox1.Style = 68
;endregion 
 
;region === ImageList ===================================================== 
$ImageList1 = $System.ImageList
$ImageList1.ImageSize = 16,16
$ImageList1.TransparentColor = 255,0,255
$ImageList1.AddStrip($System.Bitmap.FromBase64String(fnSchemaBrowser))
;endregion 
 
;region === Main Form ===================================================== 
$Form = $System.Form()
$Form.DockPadding = 1,1,1,1
 
$Form.Icon = $ImageList1.Images(1)
$Form.FontName = "Tahoma"
$Form.Size = 800,600
$Form.Text = "Active Directory Attribute Browser"
$Form.Center()
;endregion 
 
;region === Clipboard ===================================================== 
$Form.Clipboard1 = $Form.Controls.TextBox("",0,0,0,0)
$Form.Clipboard1.Hide
;endregion 
 
;region === Menus ========================================================= 
$Form.Menu = $System.MainMenu()
 
;region === File Menu ===================================================== 
$Form.FileMenu = $Form.Menu.MenuItems.Add("&File")
 
$Form.FileMenu.ExitApp = $Form.FileMenu.MenuItems.Add("Exit")
$Form.FileMenu.ExitApp.onclick = "Quit()"
;endregion 
 
;endregion 
 
;region === Toolbar ======================================================= 
$Form.ToolGroupBox = $Form.Controls.GroupBox()
$Form.ToolGroupBox.Height = 30
$Form.ToolGroupBox.Dock = 1
 
$Form.Console = $Form.ToolGroupBox.ToolButton("",2,2,26,26)
$Form.Console.Style = 1
$Form.Console.FlatStyle = 1
$Form.Console.Pushed = 1
$Form.Console.Icon = $ImageList1.Images(4)
$Form.Console.onclick = "fnOnShowHide()"
$Form.Console.ToolTipText = "Show/Hide Console Tree"
;endregion 
 
;region === Status Bar ==================================================== 
$Form.StatusGroupBox = $Form.GroupBox()
$Form.StatusGroupBox.Height = 20
$Form.StatusGroupBox.Dock = 2
;endregion 
 
;region === TreeView ====================================================== 
$Form.TreeView1 = $Form.TreeView()
$Form.TreeView1.Dock = 3
$Form.TreeView1.HideSelection = 0
$Form.TreeView1.ImageList = $ImageList1
$Form.TreeView1.OnAfterSelect = "fnOnAfterSelect()"
$Form.TreeView1.Width = $Form.ClientWidth / 4
$Form.TreeView1.Tag = $Form.TreeView1.Width
$Form.TreeView1.Sorted = 1
;endregion 
 
;region === Splitter ====================================================== 
$Form.Splitter1 = $Form.Splitter()
$Form.Splitter1.Dock = 3
;endregion 
 
$Form.GroupBox1 = $Form.Controls.GroupBox()
$Form.GroupBox1.Dock = 5
 
;region === Listview Label ================================================ 
$Form.Label1 = $Form.GroupBox1.Label()
$Form.Label1.BorderStyle = 2
$Form.Label1.Dock = 1
$Form.Label1.Height = 20
$Form.Label1.TextAlign = 16
;endregion 
 
;region === ListView ====================================================== 
$Form.ListView1 = $Form.GroupBox1.ListView()
$Form.ListView1.Dock = 5
$Form.ListView1.SmallImageList = $ImageList1
 
$ = $Form.ListView1.Columns.Add("Name",0.35*$Form.ListView1.ClientWidth)
$ = $Form.ListView1.Columns.Add("Syntax",0.25*$Form.ListView1.ClientWidth)
$ = $Form.ListView1.Columns.Add("Value Type",0.15*$Form.ListView1.ClientWidth)
$ = $Form.ListView1.Columns.Add("Type",0.15*$Form.ListView1.ClientWidth)
;endregion 
 
fnAddRootItems()
$Form.Show 
;endregion 
 
While $Form.Visible 
   $=Execute($Form.DoEvents) 
Loop
 
Exit 1
 
;region === Functions ===================================================== 
 
Function fnAddRootItems()
   Dim $objSchema,$node,$child,$item
   $objSchema = GetObject("LDAP://schema")
   $objSchema.Filter = "Class",""
   
   $node = $Form.TreeView1.Nodes.Add($objSchema.ADsPath,0,0)
   $node.Tag = $objSchema.ADsPath
   
   For Each $ in $objSchema
      $child = $node.Nodes.Add($.Name,1,1)
   Next
   
   $Form.TreeView1.SelectedNode = $node
   $node.Expand()
EndFunction
 
Function fnCopy()
	$Form.Clipboard1.Text = $Form.Text
	$Form.Clipboard1.SelectionLength = Len($Form.Clipboard1.Text)
	$Form.Clipboard1.Copy
EndFunction	
 
Function fnOnAfterSelect()
   Dim $node,$item,$objClass,$objSchemaClass,$strAttribute,$objAttribute
   $node = $Form.TreeView1.SelectedNode
   
   $objClass = GetObject("LDAP://schema/"+$node.Text)
   $objSchemaClass = GetObject($objClass.Parent)
   
   If $objClass.Parent
      $Form.Text = "Active Directory Attribute Browser - " + $objClass.ADsPath
   Else
      $Form.Text = "Active Directory Attribute Browser"
   EndIf
   $Form.Cursor = $System.CursorStyle.WaitCursor
   $Form.ListView1.BeginUpdate()
   $Form.ListView1.Items.Clear()
    
   ; Mandatory attributes 
   For Each $strAttribute in $objClass.MandatoryProperties
     $Item = $Form.ListView1.Items.Add($strAttribute,3)
     $objAttribute = $objSchemaClass.GetObject("Property",$strAttribute)
     $Item.SubItems(1).Text = $objAttribute.Syntax
     $Item.SubItems(2).Text = Iif($objAttribute.MultiValued,"Multi-valued","Single-valued")
     $Item.SubItems(3).Text = "Mandatory"
   Next
   
   ; Optional attributes 
   For Each $strAttribute in $objClass.OptionalProperties
     $Item = $Form.ListView1.Items.Add($strAttribute,2)
     $objAttribute = $objSchemaClass.GetObject("Property",$strAttribute)
     $Item.SubItems(1).Text = $objAttribute.Syntax
     $Item.SubItems(2).Text = Iif($objAttribute.MultiValued,"Multi-valued","Single-valued")
     $Item.SubItems(3).Text = "Optional"
   Next
   
   $Form.Label1.Text = " " + $node.Text + "    " + $Form.ListView1.Items.Count + " objects"
   
   $Form.ListView1.Tag = $node
   $Form.ListView1.EndUpdate()
   $Form.Cursor = $System.CursorStyle.Default
EndFunction
 
Function fnOnShowHide()
   If $Form.TreeView1.Visible
      $Form.TreeView1.Hide
      $Form.Splitter1.Hide
      $Form.GroupBox1.Left = 0
      $Form.GroupBox1.ClientWidth = $Form.ClientWidth
      $Form.Refresh()
   Else
      $Form.TreeView1.Show
      $Form.Splitter1.Show
      $Form.GroupBox1.Dock = 5
      $Form.Refresh()
   EndIf
EndFunction
 
Function fnSchemaBrowser()
   $fnSchemaBrowser="
      Qk02GAAAAAAAADYAAAAoAAAAYAAAABAAAAABACAAAAAAAAAYAAAAAAAAAAAAAAAAAAAAAAAA
      /wD/AP8A/wD/AP8AtqOXAJF+bwCIcWEAfmdUAHFZRgBxWUYAcVlGAGRJNQCrlYcA/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wCgUCAA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/ACBwkAD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AH19fQAgICAAExMTAG9vbwD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wAAAAAAAAAAAAAAAAAAAAAA/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8Anop6AMC7uADTrJUAtqOXANOslQC2o5cAtqOXANOslQBkSTUA
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8AsKCQANBwQADAcEAAoFAgAHBIMABgSDAAYEgwAGBI
      MABgUEAAYJiwAEDQ4AAgcJAAUFBAAP8A/wDAoJAAYEgwAGBIMABgSDAAYEgwAGBIMABgSDAA
      YEgwAGBIMABgSDAAYEgwAGBIMAD/AP8A/wD/AP8A/wD/AP8AgoKCAAAAAAD///8AAAAAAAAA
      AABYWFgAYEgwAGBIMABgSDAAYEgwAGBIMABgSDAA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AAAAAAD///8A////AP///wD///8A
      AAAAAP8A/wD/AP8A/wD/AP8A/wD/AP8Anop6APn//wD01sgA9NbIAPTWyAD01sgAamzVALaj
      lwBUQzcA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A0HBAAP+gYAD/sIAA4IhgAKBYMADw4NAA
      8NjQAPDQwACAsMAAwPj/AKDw/wBg4P8AIGiQAP8A/wDAqJAA//jwAP/w4ADw6OAA8ODQAPDQ
      wADwyLAA4MCgAOC4oADgsJAA4KiQAGBIMAD/AP8A/wD/AP8A/wD/AP8AODg4AP///wDAwMAA
      ////AAAAAAAAAAAA8MiwAODAoADguKAA4KiQAOCokABgSDAA/wD/AP8A/wD/AP8A/wD/AP8A
      /wCAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAA
      gAAAAP8A/wD/AP8AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAP///wD///8A////AAAA
      AAD///8A////AAAAAAD/AP8A/wD/AP8A/wD/AP8Anop6APn//wD01sgA9NbIAPTWyAD01sgA
      9NbIANOslQBbS0EA/wD/AP8A/wD/AP8A/wD/AP8A/wDgmHAA/8CgAP+wgADgiGAAoFgwAMCo
      kADAsKAAwLCgAMCooACwsKAAgLDAAMD4/wCg+P8AQNDwADBIYADAqKAA//jwAMCooACwoKAA
      8OjgALCgkACwmJAAsJiQALCYkACwmJAA4LCQAGBIMAD/AP8A/wD/AP8A/wD/AP8AQUFBAMDA
      wAAAAAAAwMDAAP///wAJCQkAsJiQALCYkACwmJAAsJiQAOCokABgSDAA/wD/AP8A/wD/AP8A
      /wD/AP8A/wCAAAAA////AP///wD///8A////AP///wCAAAAAwMDAAMDAwADAwMAAwMDAAMDA
      wADAwMAAgAAAAP8A/wD/AP8AAAAAAP///wD///8A////AP///wAAAAAA////AP///wD///8A
      ////AAAAAAAAAAAA////AP///wAAAAAA/wD/AP8A/wD/AP8Aq5WHAPn//wD13dIA9d3SAPXd
      0gD01sgA9NbIAMSwpABxWUYA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A4JhwAP/AoACgWDAA
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AICwwADA+P8AYJiwAP8A/wDAqKAA//jwAP/4
      8AD/+PAA//DgAPDo4ADw4NAA8NDAAPDIsADgwKAA4LigAGBIMAD/AP8A/wD/AP8A/wD/AP8A
      goKCAAAAAAAAAAAAAAAAAMDAwABvb28A8ODQAPDQwADwyLAA4MCgAOC4oABgSDAA/wD/AP8A
      /wD/AP8A/wD/AP8A/wCAAAAA////AP///wD///8A////AP///wCAAAAAwMDAAMDAwADAwMAA
      wMDAAMDAwADAwMAAgAAAAP8A/wD/AP8AAAAAAP///wD///8A////AP///wAAAAAA////AAAA
      AAAAAAAAAAAAAAAAAAAAAAAAAAAAAP///wAAAAAA/wD/AP8A/wD/AP8Aq5WHAPn//wD13dIA
      9d3SAPXd0gD13dIA9d3SAMSwpABxWUYA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8AwKCQAOCY
      cABwUDAA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/ALCwoACAsMAAYFhAAP8A/wDAqKAA
      //jwALCooACwoKAA//jwALCgkACwmJAAsJiQALCYkACwmJAA4MCgAGBIMAD/AP8A/wD/AP8A
      /wD/AP8AwKigAIKCggA4ODgALi4uAIKCggCwoJAAsJiQALCYkACwmJAAsJiQAODAoABgSDAA
      /wD/AP8A/wD/AP8A/wD/AP8A/wCAAAAA////AAAAAAAAAAAAAAAAAP///wCAAAAAwMDAAMDA
      wADAwMAAAAAAAMDAwADAwMAAgAAAAP8A/wD/AP8AAAAAAP///wD///8AgAAAAIAAAAAAAAAA
      ////AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAP///wAAAAAA/wD/AP8A/wD/AP8Aq5WHAPn/
      /wD45dsA+OXbAPjl2wD13dIA9d3SAMSwpAB+Z1QA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      wKigAP/4/wBgSDAA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AMCooADw0MAAYEgwAP8A
      /wDAsKAA//jwAP/48AD/+PAA//jwAP/48AD/8OAA8OjgAPDg0ADw0MAA8MiwAGBIMAD/AP8A
      /wD/AP8A/wD/AP8AwLCgAP/48AD/+PAA//jwAP/48AD/+PAA//DgAPDo4ADw4NAA8NDAAPDI
      sABgSDAA/wD/AP8A/wD/AP8A/wD/AP8A/wCAAAAA////AP///wD///8A////AP///wCAAAAA
      wMDAAMDAwAAAAAAAAAAAAMDAwADAwMAAgAAAAP8A/wD/AP8AAAAAAP///wD///8AgAAAAMDA
      wAAAAAAA////AP///wD///8A////AAAAAAAAAAAA////AP///wAAAAAA/wD/AP8A/wD/AP8A
      tqOXAPn//wD5//8A+f//APn//wD5//8A+f//APXd0gB+Z1QA/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8AwLCgAP/4/wBgSDAA/wD/AP8A/wD/AP8AEDCgAKaYrAD/AP8A/wD/AMCooADw2NAA
      YEgwAP8A/wDAsKAA//jwAP/48AD/+PAA//jwAP/48AD/+PAAwMjAAEBgcADw4NAA8NDAAGBI
      MAD/AP8A/wD/AP8A/wD/AP8AwLCgAP/48AD/+PAA//jwAP/48AD/+PAA//jwAMDIwABAYHAA
      8ODQAPDQwABgSDAA/wD/AP8A/wD/AP8A/wD/AP8A/wCAAAAA////AAAAAAAAAAAAAAAAAP//
      /wCAAAAAwMDAAAAAAAAAAAAAAAAAAMDAwADAwMAAgAAAAP8A/wD/AP8AAAAAAP///wD///8A
      ////AP///wD///8AAAAAAP///wD///8A////AAAAAAD///8A////AAAAAAD/AP8A/wD/AP8A
      /wD/AP8AtqOXANzRygC2o5cAq5WHAKuVhwCeinoAkX5vAJF+bwCRfm8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8AwLCgAP/4/wBgSDAA/wD/AP8A/wAwSMAAEEjgABAwkACelagA/wD/AMCw
      oADw4NAAYEgwAP8A/wDAsKAA////AODo8ABgeIAA4ODgAP/48ADAyNAAUGBwADCo0AAgOEAA
      sKCgAGBIMAD/AP8A/wD/AKmzjgBAgFAAwLCgAP///wDg6PAAYHiAAODg4AD/+PAAwMjQAFBg
      cAAwqNAAIDhAALCgoABgSDAA/wD/AP8A/wCps44AQIBQAP8A/wCAAAAA////AP///wD///8A
      ////AP///wCAAAAAwMDAAMDAwAAAAAAAAAAAAMDAwADAwMAAgAAAAP8A/wD/AP8AAAAAAP//
      /wD///8AgAAAAIAAAAD///8AgAAAAAAAAAD///8A////AP///wD///8AAAAAAP8A/wD/AP8A
      fMTcAJLV5ACe6PQAILDgAJLo9ACg2OAAlsvbAPns5gD57OYA+ezmANW6qwCRfm8A/wD/AP8A
      /wD/AP8A/wD/AInI3ACS1eQAgNjgAEDA8ABwwMAAUJCgACCA4ADA0P8AYIj/ACBQ4AAQMKAA
      UEBQAGBIMAD/6OAAYEgwAP8A/wDQsKAA////AJCosACA0OAAUGBwALC4wABQYHAAYMDgAFBg
      cAAwuPAAECgwABAwQAAQKDAAdnR0AEB4QABQqGAA0LCgAP///wCQqLAAgNDgAFBgcACwuMAA
      UGBwAGDA4ABQYHAAMLjwABAoMAAQMEAAECgwAHZ0dABAeEAAUKhgAP8A/wCAAAAA////AAAA
      AAAAAAAAAAAAAP///wCAAAAAwMDAAMDAwADAwMAAAAAAAMDAwADAwMAAgAAAAP8A/wD/AP8A
      AAAAAP///wD///8AgAAAAMDAwAD///8A////AP///wAAAAAAAAAAAAAAAAAAAAAAAAAAAP8A
      /wD/AP8Apt/qADC44ACQ8P8AYMDgAJDw/wAwuOAAoNjgAPn//wD5//8A+f//APn//wCeinoA
      /wD/AP8A/wD/AP8A/wD/AKbf6wAwuOAAgOj/AGDI4ACQ8P8AMLjgAKDg/wBAcP8AwND/AHCQ
      /wAwWOAAEDCgAPDw8AD/8OAAYEgwAP8A/wDQuKAA////AODo8ACQqLAAgODwAFBgcACA0OAA
      UGBwAGDQ8ABAYHAAMLDgACCY0AAgiLAAIFBwAFCIYABQsGAA0LigAP///wDg6PAAkKiwAIDg
      8ABQYHAAgNDgAFBgcABg0PAAQGBwADCw4AAgmNAAIIiwACBQcABQiGAAULBgAP8A/wCAAAAA
      ////AP///wD///8A////AP///wCAAAAAwMDAAMDAwADAwMAAwMDAAMDAwADAwMAAgAAAAP8A
      /wD/AP8AAAAAAP///wD///8A////AP///wD///8A////AP///wD///8A////AP///wD///8A
      AAAAAP8A/wD/AP8Anuf0AJDw/wDA+P8AsOjwAMD4/wCQ8P8AoNjgALajlwCrlYcAq5WHAJ6K
      egCeinoA/wD/AP8A/wD/AP8A/wD/AJ7o9QCQ8P8AwPj/ALDo8ADA+P8AkPD/AJDY4ACwoKAA
      UHjwANDY/wAwUOAAsKCgAMCokADAoJAAsKCQAP8A/wDQuKAA0LigANC4oADAsKAAkKiwAIDg
      8ABQYHAAgODwAEBYcABg0PAAUMjwAEDA8AAgsOAAIKDQAGCYcABQuHAA0LigANC4oADQuKAA
      wLCgAJCosACA4PAAUGBwAIDg8ABAWHAAYNDwAFDI8ABAwPAAILDgACCg0ABgmHAAULhwAP8A
      /wCAAAAA////AP///wD///8A////AP///wCAAAAAwMDAAMDAwADAwMAAwMDAAMDAwADAwMAA
      gAAAAP8A/wD/AP8AAAAAAP///wD///8AgAAAAIAAAAD///8AgAAAAIAAAACAAAAAgAAAAP//
      /wD///8AAAAAAP8A/wD/AP8AIKjgAFDA4ACw6PAA8P//ALDo8ABQwOAAMLjgAPjl2wD13dIA
      9NbIANW6qwCrlYcA/wD/AP8A/wD/AP8A/wD/ACCo4ABQwOAAsOjwAPD//wCw6PAAUMDgADC4
      4AD/AP8A/wD/AEh19wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AJCosACA4PAAQFhwAIDg8ABw2PAAYNDwAFDI8ABAwPAAMLjwAHCogABgwIAA/wD/AP8A
      /wD/AP8A/wD/AP8A/wCQqLAAgODwAEBYcACA4PAAcNjwAGDQ8ABQyPAAQMDwADC48ABwqIAA
      YMCAAP8A/wCAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAAgAAAAIAA
      AACAAAAAgAAAAP8A/wD/AP8AAAAAAP///wD///8AgAAAAMDAwAD///8A////AP///wD///8A
      ////AP///wD///8AAAAAAP8A/wD/AP8Anuf0AJDw/wDA+P8AsOjwAMD4/wCQ8P8AoNjgAPns
      5gD45dsA9d3SANW6qwC2o5cA/wD/AP8A/wD/AP8A/wD/AJ7o9QCQ8P8AwPj/ALDo8ADA+P8A
      kPD/AJ7m8QD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wCQqLAAgODwAIDg8ACA4PAAcNjwAGDQ8ABgsNAAgIiQALDAoACQ0KAA
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8AkKiwAIDg8ACA4PAAgODwAHDY8ABg0PAAYLDQAICI
      kACwwKAAkNCgAP8A/wCAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAAgAAAAIAAAACAAAAA
      gAAAAIAAAACAAAAAgAAAAP8A/wD/AP8AAAAAAP///wD///8A////AP///wD///8A////AP//
      /wD///8A////AP///wD///8AAAAAAP8A/wD/AP8Apt/qADC44ACQ8P8AYMDgAJDw/wAwuOAA
      oNjgAPn//wD5//8A+f//ANvc2gDEsKQA/wD/AP8A/wD/AP8A/wD/AKbf6wAwuOAAkPD/AGDA
      4ACQ8P8AMLjgAKXY3QD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8AkKiwAJCgsACQoKAAgJigAICQoACAiJAAvrezAKC4
      oACwwKAA/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AJCosACQoLAAkKCgAICYoACAkKAA
      gIiQAL63swCguKAAsMCgAP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA
      AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAP8A/wD/AP8AfMTcAJLV5ACe6PQAILDgAJLo
      9ACg2OAAlsvbAMSwpADEsKQAxLCkALajlwDXysIA/wD/AP8A/wD/AP8A/wD/AHzE3QCS1eQA
      nubxACCw4ACS5vMApdjdAJXI1QD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      /wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A/wD/AP8A
      "
EndFunction
;endregion

Top
#146769 - 2005-08-29 09:52 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
NTDOC Administrator Offline
Administrator
*****

Registered: 2000-07-28
Posts: 11629
Loc: CA
Chris,

Thanks for the browser form but I'm not sure I like where this is starting to go. This form looks like KiXtart 4.50 or newer is mandatory (not that big of a deal), however it looks like you posted a TOKENIZED UDF as part of the scrpt which to me means a couple of things.

1. Idea/Method/Learning on the board is reduced and or removed by such postings.
2. Thought of proprietary code is potentially portrayed when it may or may not be, could easily be retrofitted VBS or other code.
3. Debugging of Tokenized code is impossible for someone without the SOURCE code.

IMHO I would rather not see TOKENIZED code posted, but can not stop you if that is what you feel you want to do.
Top
#146770 - 2005-08-29 09:54 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
Chris S. Offline
MM club member
*****

Registered: 2002-03-18
Posts: 2368
Loc: Earth
Doc, that is a base64 bitmap strip for the customzied icons you see in the screenshot. There is no tokenized code posted.
Top
#146771 - 2005-08-29 09:55 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
NTDOC Administrator Offline
Administrator
*****

Registered: 2000-07-28
Posts: 11629
Loc: CA
Well after reviewing the code I'll recend my comments Chris, as it appears you're using the the code as a bitmap image and not a Tokenized function..

However, ideas of posting TOKENIZED scripts for others still stands as I think it is not a good idea.
Top
#146772 - 2005-08-29 09:56 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
NTDOC Administrator Offline
Administrator
*****

Registered: 2000-07-28
Posts: 11629
Loc: CA
LOL you're too fast. I tried to get on MSN but it won't connect for some reason. Then I saw what the code was doing and posted a recending comment.
Top
#146773 - 2005-08-29 09:58 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
Lonkero Administrator Offline
KiX Master Guru
*****

Registered: 2001-06-05
Posts: 22346
Loc: OK
but sounds like you have been thinking about doing that yourself.
how else you could have made the assumption here?
_________________________
!

download KiXnet

Top
#146774 - 2005-08-29 10:07 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
NTDOC Administrator Offline
Administrator
*****

Registered: 2000-07-28
Posts: 11629
Loc: CA
Nope, because I've seen TOKENIZED code which looks sort of similar.
Top
#146775 - 2005-08-29 10:27 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
Lonkero Administrator Offline
KiX Master Guru
*****

Registered: 2001-06-05
Posts: 22346
Loc: OK
sure, but also lonkenized code looks similar...
_________________________
!

download KiXnet

Top
#146776 - 2005-08-29 11:51 PM Re: Active Directory Attribute Browser - Browse your schema for AD attributes
Chris S. Offline
MM club member
*****

Registered: 2002-03-18
Posts: 2368
Loc: Earth
Quote:

sure, but also lonkenized code looks similar...



Nah, base64 is easier to read. ;-)
Top
Page 1 of 1 1


Moderator:  Shawn, ShaneEP, Ruud van Velsen, Arend_, Jochen, Radimus, Glenn Barnas, Allen, Mart 
Hop to:
Shout Box

Who's Online
0 registered and 2449 anonymous users online.
details
Newest Members
batdk82, StuTheCoder, M_Moore, BeeEm, min_seow
17885 Registered Users
My Cookies · Mark all read Powered by UBB.threads™ Contact Us · KiXtart.org website · Top

Generated in 0.068 seconds in which 0.03 seconds were spent on a total of 12 queries. Zlib compression enabled.
Search the board with:
superb Board Search
or try with google:
Google
Web kixtart.org