function SetStaticIPOptions($Setting,$Value,optional $remotepc)
  dim $objWMIService, $colitems, $objnetadapter,$,$IP[0],$SM[0],$WS1,$WS2
  $SetStaticIPOptions=1
  if $remotepc=""
    $remotepc="."
  endif
  $objWMIService = GetObject("winmgmts:\\" + $remotepc + "\root\cimv2")
  if @error
    exit @error
  endif
  $colItems = $objWMIService.ExecQuery("Select * from Win32_NetworkAdapterConfiguration where IPEnabled=-1")
  For Each $objNetAdapter In $colItems
    Select 
      case $setting="DNSServers" 
        $=$objNetAdapter.SetDNSServerSearchOrder(split($value,","))
        if @error
          exit @error
        else
          $SetStaticIPOptions=0
        endif
      case $setting="WINSServers"
        $WS1=split($value,",")[0]
        if ubound(split($value,","))>0
          $WS2=split($value,",")[1]
        else
          $WS2=""
        endif
        $=$objNetAdapter.SetWINSServer($WS1,$WS2) 
        if @error
          exit @error
        else
          $SetStaticIPOptions=0
        endif
      case $setting="DNSDomain"
        $=$objNetAdapter.SetDNSDomain($value)
        if @error
          exit @error
        else
          $SetStaticIPOptions=0
        endif
      case $setting="DefaultGW"
        $=$objNetAdapter.SetGateways(split($value,","))
        if @error
          exit @error
        else
          $SetStaticIPOptions=0
        endif
      case $setting="IPAddress"
        if instr($value,",")>0
          $IP[0]=split($Value,",")[0]
          $SM[0]=split($value,",")[1]
          $=$objNetAdapter.EnableStatic($IP, $SM)
          if @error
            exit @error
          else
            $SetStaticIPOptions=0
          endif
        endif
    endselect
  Next
endfunction