• 1. Must be able to handle a MIN/MAX input range
  
• 2. Must support both whole and decimal numbers
  
• 3. Must not readily (obviously detectable pattern) duplicate numbers in successive calls including small range of 1-10
  
• 4. Must support calls similar to this
  Random(0.000, 0.999)
  Random(1, 5)
  Random(500, 10000)
  
• 5. Use of seed or method to ensure randomness should be controlled by the UDF
  
• Example:
  For $ = 1 To 50
     Random(0.000, 0.999) ?
  Next
  
• 6. Must support Explicit and NoVarsInStrings just like all other UDFs
  

• 1
  4
  6
  6
  8
  9
  

function Random($min, $max, optional $seed) 
  if $seed 
    srnd($seed) 
  endif 
  $random = rnd($max) 
  do 
    $random = rnd($max) 
  until $random >= $min and $random <= $max 
Endfunction 

function random($min, $max, optional $seed) 
   DIM $i, $burn, $nul 
   srnd((-1)*@ticks*(val($seed)+1)) 
   $burn = rnd(50) 
   for $i = 1 to $burn 
      $nul = rnd($max) 
   next 
   $random = rnd($max) 
   while $random < $min or $random > $max 
      $random = rnd($max)    
   loop    
endfunction 

function random($min,optional $max) 
  dim $seed 
  do 
    $seed=@ticks 
    do 
    until $seed<>@ticks 
      SRND(IIF(@TICKS<0,(-(@TICKS*@msecs*7)),@TICKS*@MSECS*7)) 
    $random=rnd($max) 
  until $random>=$min and $random<=$max 
Endfunction

Function Randomize() 
 Dim $ticks $ticks = @ticks 
 If $ticks < 0 
  $ticks = -1 * $ticks 
 EndIf 
 SRND($ticks) 
EndFunction 

for $i = 0 to 20
 ?"rnd=" 0.001 * rnd(1000)
next

$=SetOption("Explicit","ON")
 
Dim $i
$i=rng(@TICKS)
For $i=1 to 50 rng() ? Next
 
Function rng(Optional $iSeed)
	Dim $vDiscard
	If Not IsDeclared($_RNG_PERSISTENT) Global $_RNG_PERSISTENT EndIf
	If VarType($iSeed) $_RNG_PERSISTENT=CInt($iSeed) EndIf
	$_RNG_PERSISTENT=CInt(&FFFFFFFFFF) & CInt($_RNG_PERSISTENT)
	$_RNG_PERSISTENT=CInt($_RNG_PERSISTENT*1103515245 +12345)
	; Emulate 16 bit shift right ($rng>>16)
	$rng=DecToHex($_RNG_PERSISTENT)
	$rng=SubStr($rng,2,Len($rng)-3)
	If $rng="" $rng=0 EndIf
	; Convert hex to Decimal
	$vDiscard=Execute("$$rng=&"+$rng+" & &FFFFFFFF")
EndFunction

Break ON
$=SetOption("Explicit","ON")
 
Dim $i,$r,$max,$min
$r=rng(0,0,@TICKS)
While "TRUE" AND Not KBHit()
	rng(10.00,20.99) ?
Loop
 
Function rng($iMin,$iMax,Optional $iSeed)
	Dim $vDiscard,$sDecimal,$i,$iFactor
	$sDecimal="."
	; Establish how many decimals to use
	If InStr($iMin,$sDecimal) $iFactor=Len($iMin)-InStrRev($iMin,$sDecimal) EndIf
	If InStr($iMax,$sDecimal) $i=Len($iMax)-InStrRev($iMax,$sDecimal) EndIf
	If $i>$iFactor $iFactor=$i EndIf
	$iFactor=CInt("1"+Left("000000",$iFactor))
	; Ensure min and max are in the right order
	If $iMax < $iMin $i=$iMin $iMin=$iMax $iMax=$i EndIf
	$iMax=$iMax * $iFactor
	$iMin=$iMin * $iFactor
	; Fix max to base (0)
	$iMax=($iMax-$iMin+1)
	If Not IsDeclared($_RNG_PERSISTENT) Global $_RNG_PERSISTENT EndIf
	If VarType($iSeed) $_RNG_PERSISTENT=CInt($iSeed) EndIf
	$_RNG_PERSISTENT=1103515245*$_RNG_PERSISTENT+12345
	; Emulate 16 bit shift right ($rng>>16)
	$rng=DecToHex($_RNG_PERSISTENT)
	$rng=SubStr($rng,2,Len($rng)-3)
	If $rng="" $rng=0 EndIf
	; Convert hex to Decimal and fix to scope
	; $vDiscard=Execute("$$rng=&"+$rng)
	$vDiscard=Execute("$$rng=CDbl(((&"+$rng+" mod "+$iMax+") + "+$iMin+")) / "+$iFactor)
EndFunction

• 
  1
  8
  5
  5
  1
  5
  5
  3
  10
  1
  
• 
  4
  2
  2
  10
  1
  10
  10
  6
  2
  1
  

• $iSampleSet=50 Every result
  
• $iSampleSet=100 Even numbers
  
• $iSampleSet=250 Numbers divisible by 5
  
• $iSampleSet=5000 Hundreds

Break ON
$=SetOption("Explicit","ON")
$=SetOption("ASCII","ON")
$=SetOption("NoVarsInStrings","ON")
 
Dim $r,$iMaxScale,$iRow,$iSampleSize,$iSampleRate,$iBase,$iSampleCount
Dim $iResults[50]
 
$iMaxScale=100
$iSampleSize=5000
$iBase=1234
 
CLS
 
DrawGraph($iMaxScale,$iResults)
$iSampleSize=Int($iSampleSize/50)*50
At(23,40) "Sample size=" $iSampleSize ", Base=" $iBase
 
$iSampleRate=$iSampleSize/50
 
$r=rng(0,0,@TICKS)
While "TRUE" AND Not KBHit()
	$r=rng($iBase,$iBase+$iSampleSize-1)
	$iSampleCount=$iSampleCount+1
	$r=$r-$iBase
	; Only record results from sample
	If Not ($r mod $iSampleRate)
		At(23,0) "Last: " $r "      "
		$r=$r/$iSampleRate
		At(23,15) "Sample Count: " $iSampleCount
		$iResults[$r]=$iResults[$r]+1
		$iRow=$iResults[$r]/($iMaxScale/20)
		If $iRow>20
			$iMaxScale=$iMaxScale*2
			DrawGraph($iMaxScale,$iResults)
		Else
			If Not (($r+1) mod 5) Color y+/n EndIf
			If $iRow AT(22-$iRow,$r+11) "*" EndIf
			Color w/n
		EndIf
	EndIf
Loop
Get $r
 
Function DrawGraph($iMaxScale,$iResults)
	Dim $iRow,$iCol
	At(1,0) Right("          "+$iMaxScale,9)
	For $iRow = 1 to 21 At($iRow,10) "|" Next
	At(22,10) "+"
	For $iCol=0 to 49
		If Not (($iCol+1) mod 5) Color y+/n EndIf
		At(22,$iCol+11) "-"
		For $iRow=1 to 20
			At(22-$iRow,$iCol+11)
			If ($iResults[$iCol]/($iMaxScale/20)) >= $iRow "*" Else	" " EndIf
		Next
		Color w/n
	Next
	Exit 0
EndFunction
 
Function rng($iMin,$iMax,Optional $iSeed)
	Dim $vDiscard,$sDecimal,$i,$iFactor
	Dim $		; Fixes problem with "NoVarsInStrings" set to "ON"
	$sDecimal="."
	; Establish how many decimals to use
	If InStr($iMin,$sDecimal) $iFactor=Len($iMin)-InStrRev($iMin,$sDecimal) EndIf
	If InStr($iMax,$sDecimal) $i=Len($iMax)-InStrRev($iMax,$sDecimal) EndIf
	If $i>$iFactor $iFactor=$i EndIf
	$iMax=CDbl($iMax) $iMin=CDbl($iMin)
	$iFactor=CInt("1"+Left("000000",$iFactor))
	; Ensure min and max are in the right order
	If $iMax < $iMin $i=$iMin $iMin=$iMax $iMax=$i EndIf
	$iMax=$iMax * $iFactor
	$iMin=$iMin * $iFactor
	; Fix max to base (0)
	$iMax=($iMax-$iMin+1)
	If Not IsDeclared($_RNG_PERSISTENT) Global $_RNG_PERSISTENT EndIf
	If VarType($iSeed) $_RNG_PERSISTENT=CInt($iSeed) EndIf
	$_RNG_PERSISTENT=1103515245*$_RNG_PERSISTENT+12345
	; Emulate 16 bit shift right ($rng>>16)
	$rng=DecToHex($_RNG_PERSISTENT)
	$rng=SubStr($rng,2,Len($rng)-3)
	If $rng="" $rng=0 EndIf
	; Convert hex to Decimal and fix to scope
	$vDiscard=Execute("$$rng=CDbl((((&"+$rng+") mod "+$iMax+") + "+$iMin+")) / "+$iFactor)
EndFunction