Break On
Dim $SO,$Pause
$SO=SetOption('Explicit','On')
$SO=SetOption('NoVarsInStrings','On')
$SO=SetOption('WrapAtEOL','On')
 
Dim $K1,$K2,$Key,$KValue,$Value,$Index
$K1='HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{5E6AB780-7743-11CF-A12B-00AA004AE837}\Count'
$K2='HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count'
; Set the forground color to WHITE and the background color to LIGHT RED 
COLOR 'w+/r+'
? '********************'
? '* [ EASTER EGG 1 ] *'
? '********************'
COLOR 'y+/n'
$KValue=ArrayEnumValue($K1+'\'+$Key)
$Index=0
For Each $Value In $KValue
	? 'Easter Egg: '+$Index + '  ' + Rot13($Value)
	$Index = $Index + 1
Next
; Set the forground color to WHITE and the background color to DARK BLUE 
COLOR 'w+/b'
?
? '********************'
? '* [ EASTER EGG 2 ] *'
? '********************'
COLOR 'y+/n'
$KValue=ArrayEnumValue($K2+'\'+$Key)
$Index=0
For Each $Value In $KValue
	? 'Easter Egg: '+$Index + '  ' + Rot13($Value)
	$Index = $Index + 1
Next
 
COLOR 'w+/r+'
?? 'Press a key to continue...'
Get $Pause
 
Function ArrayEnumValue($RegSubKey)
	Dim $RetCode, $ValueCounter, $CurrentValue, $ValueArray
	If Not KeyExist($RegSubKey)
		Exit 87
	EndIf
	$ValueCounter=0
	Do
		$currentvalue=enumvalue($regsubkey,$valuecounter)
		If Not @ERROR
			ReDim PreServe $ValueArray[$ValueCounter]
			$ValueArray[$ValueCounter]=$CurrentValue
			$ValueCounter=$ValueCounter+1
		EndIf
	Until @ERROR
	$ArrayEnumValue=$ValueArray
	Exit 0
EndFunction
 
Function Rot13($s)
	DIM $i,$c, $o,$u
	$o=SetOption("CaseSensitivity","Off")
	$u = (Ubound($s) >=0)
	If $u  $s=Join($s,@CRLF) EndIf
	For $i = 1 To Len($s)
	  $c = Substr($s,$i,1)
	  Select
	    Case $c >= 'a' And $c <= 'm'
	      $c = Chr(Asc($c)+13)
	    Case $c >= 'n' And $c <= 'z'
	      $c = Chr(Asc($c)-13)
	  EndSelect
	  $Rot13 = $Rot13+$c
	Next
	If $u $Rot13 = Split($Rot13,@CRLF) EndIf
	$o=SetOption("CaseSensitivity",$o)
EndFunction