Here is an example of a messagebox using IE:
Code:
$oIE=funMakeIE("Countdown timer demo",150,400)

	 

For $i = 10 To 0 Step -1

	Select

	Case $i<3 $COLOUR="RED"

	Case $i<6 $COLOUR="YELLOW"

	Case "Default" $COLOUR="GREEN"

	EndSelect

	$oIE.document.body.innerHTML="<CENTER><FONT COLOR="+$COLOUR+" SIZE=7>Countdown: "+$i+"</FONT></CENTER>"

	Sleep 0.5

Next

$oIE.document.body.innerHTML="<CENTER><FONT COLOR=RED SIZE=7><B>**BOOM**</B></FONT></CENTER>"

Sleep 3

	 

$oIE.Quit

$oIE=0

Exit 0

 

; -------------------------------------------------------

; Ignore everything below here - this is black-box magic.

; -------------------------------------------------------

 

 



Function funMakeIE($sTitle,$iHeight,$iWidth)

	$funMakeIE=CreateObject("InternetExplorer.Application")

	If $funMakeIE

		; Remove clutter

		$funMakeIE.toolbar=0 $funMakeIE.menubar=0 $funMakeIE.addressbar=0 $funMakeIE.statusbar=0

		; Load dummy

		$funMakeIE.navigate("about:blank")

		funWait($funMakeIE)

	Else

		funError("Cannot create IE object")

		Exit 1406

	EndIf

 

	$funMakeIE.document.write("<HTML>

	<HEAD>

 	<!--

   	Hand crafted script

   	Created R. Howarth March 2004

 	-->

 	<TITLE>"+$sTitle+"</TITLE>

 	<SCRIPT Language=JavaScript>

  	function funDispatcher(s){

  		frmMain.sStatus.value+=s+';';

  	}

  	function funGetScreenSize(){

   	frmMain.screenheight.value=screen.availHeight;

   	frmMain.screenwidth.value=screen.availWidth;

  	}

 	</SCRIPT>

	</HEAD>

	<BODY onLoad='funGetScreenSize();' BGCOLOR=LIGHTGREY>

 	<FORM Name=frmMain>

 	<INPUT Type=Hidden Name=screenheight Value=''>

 	<INPUT Type=Hidden Name=screenwidth Value=''>

 	</FORM>

	</BODY>

	</HTML>")

 

	$funMakeIE.refresh()

	funWait($funMakeIE)

	$funMakeIE.height=$iHeight

	$funMakeIE.width=$iWidth

	$funMakeIE.left=(Cint($funMakeIE.document.frmMain.screenwidth.value)-$iWidth)/2

	$funMakeIE.Top=(Cint($funMakeIE.document.frmMain.screenheight.value)-$iHeight)/2

	$funMakeIE.visible=1

	funWait($funMakeIE)

	$=SetFocus($TITLE)

	$funMakeIE.visible = 1

 

	Exit 0

EndFunction

	 

Function funWait($oIE)

	While $oIE.busy AND $oIE.readystate <> 4 AND @error = 0 Loop

EndFunction


It may look a bit complicated, but you don't need to know how the functions work - just follow what is going on in the first dozen lines or so.