;hotfix Scanner

;########################

$hotfix="KB824146"

$type="SP5" ; pre sp5 hotfix



$rc=open(1,"\\server\patch\"+$hotfix,5)

$regkey = "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Updates\Windows 2000\"+$type+"\"+$hotfix

for each $machine in netview2()

	if "Windows 2000 Hotfix - KB824146"=ReadValue("\\"+$machine+"\"+$regkey, "Description")

		$rc=writeline(1,$machine+","+ReadValue("\\"+$machine+"\"+$regkey, "InstalledDate")+@crlf)

	else

		$rc=writeline(1,$machine+",not installed"+@crlf)

	Endif

next

$rc=close(1)



exit 0 ;script exits here.



;FUNCTION      NetView2()

;

;AUTHOR        Jens Meyer (sealeopard@usa.net)

;

;CONTRIBUTOR   Shawn Tassie

;

;ACTION        Enumerate all announced computers in your domain

;

;VERSION       1.2 (fixed bug in SHELL string)

;              1.1

;

;DATE CREATED  2002/05/14

;

;DATE MODIFIED 2003/05/31

;

;KIXTART       4.12+

;

;SYNTAX        NetView2([Domain,Comment])

;

;PARAMETERS    DOMAIN

;              Specifies the domain to enumerate. If domain is omitted, returns a

;              list of all announced computers in the current domain.

;

;              COMMENT

;              Optional boolean to determine whether to return the associated computer

;              comment (separated by a comma from the computername)

;

;RETURNS       An array of strings representing all the computers in the domain

;

;REMARKS       This UDF returns a list of computers that are PINGable. Computers, that

;              are members of the domain but are currently not connected to the domain,

;              will not be listed. For a list of joined computers independent of whether

;              they are on- or off-line use COMNetView().

;

;              Slightly improved version of Shawn's NetView() UDF

;              at http://www.kixtart.org/cgi-bin/ultimatebb.cgi?ubb=print_topic;f=12;t=000059 

;

;DEPENDENCIES  none

;

;EXAMPLE       for each $computer in netview2()

;                ? ''+$computer

;              next

;

;KIXTART BBS   http://www.kixtart.org/cgi-bin/ultimatebb.cgi?ubb=get_topic;f=12;t=000202 

;

function NetView2(optional $domain, optional $commentflag)

  dim $array[255]

  dim $redim, $i, $j, $tempfile

  dim $filehandle, $retcode, $line

  dim $name, $comment



  $redim = 255

  $i = 0

  $j = 0

  $tempfile = '%temp%\netview.tmp'



  if $domain

    $domain = '/domain:'+trim($domain)

  endif



  if vartype($commentflag)

    $commentflag=val($commentflag)

  else

    $commentflag=0

  endif



  if exist($tempfile)

    del $tempfile

  endif



  shell '%comspec% /c net view '+$domain+' >"'+$tempfile+'"'



  if @error = 0

    $filehandle=freefilehandle()

    $retcode=open($filehandle,$tempfile)



    for $j = 1 to 5

      $line = readline($filehandle) ; skip headings

    next



    while @error = 0

      $name= trim(substr($line,3,instr($line,' ')-1))

      $comment = trim(right($line,len($line)-instr($line,' ')))

      if $commentflag

        $array[$i]=$name+','+$comment

      else

        $array[$i]=$name

      endif

      $i=$i+1

      if $i = $redim

        $redim=$redim*2

        redim preserve $array[$redim]

      endif

      $line = readline($filehandle)

    loop

    $retcode=close($filehandle)

    del $tempfile

    if $i

      redim preserve $array[$i-4]

      $netview2 = $array

      exit @error

    endif

  endif



  $netview2 = 0

  exit @error

endfunction