LonkeroAdministrator
(KiX Master Guru)
2002-09-18 09:53 AM
devel of new checker

patrick, found already a mistake... lacking of one zero on one line...

I uploaded it already, just get it there.

to others, only changes accomplished since 1.1.1:
1) corrected pronouncing of buddies
2) link points directly to last post on even multipaged topic

www.gwspikval.com/jooel/scripts/bbChecker/sources/current


MightyR1
(MM club member)
2002-09-18 09:56 AM
Re: devel of new checker

I was just about to say it didn;t work...

Wil try again with this one.

{edit}

added the new checker source to make the topic longer...

code:
;
; BBChecker II - KiXtart Bulleting Board New Post Checker
;
; Dependencies:
; Wkix32 - GUIfriendly KiXtart 4.11
; kixforms.dll - KiXForms 2.0.5
; IE5
;
; -Lonkero
;
;
Break on
Gosub "init" $msg.show
While $m.visible $=Execute($m.doevents) Loop
Gosub "final"
Exit 0

Function update()
parse()
If $s
$msg.caption=$s
$hlurl.listindex=0
$msg.value=$hlurl.text
$msg.show
$m.caption=$s+" - BBChecker II"
If $Beep Play "1g256t1d500f1g256t1d400f1g256t1d600f" EndIf
If $sslider slide($s,$hlurl.text) EndIf
EndIf
EndFunction

Function parse()
$httpObj.Open("GET",$org)
$httpObj.send()
While $httpObj.readystate<>4 $=Execute($m.doevents(1)) Sleep 0.02 Loop
$data=$httpObj.Responsetext
If 5000<Len($data)
$data=SubStr($data,InStr($data,'ubb=get_profile')+10)
$bl.clear $bll.clear
If InStr($data,'ubb=get_profile')<InStr($data,'guest(s)')
$data=SubStr($data,InStr($data,'ubb=get_profile'))
$users=SubStr($data,1,InStr($data,' and'))
For Each $user in Split($users,'</a>, ')
$bll.additem(SubStr($user,InStr($user,';u=')+3,InStr($user,'">')-3-InStr($user,';u=')),-1)
$bl.additem(SubStr($user,InStr($user,'">')+2),-1)
Next
$bl.removeitem($bl.listcount-1)
EndIf
For $c=0 to 7
$data=SubStr($data,InStr($data,'&nbsp;<a href=')+15)
$y[$c]=SubStr($data,1,InStr($data,'"')-1)
$data=SubStr($data,InStr($data,'>')+1)
$x[$c]=SubStr($data,1,InStr($data,'</a>') - 1)+" "
$x[$c]=join(Split($x[$c],"&quot;"),'"')
$x[$c]=join(Split($x[$c],"&amp;"),'&')
$data=SubStr($data,InStr($data,Chr(10))+1)
If InStr(SubStr($data,1,1),"<")
$users=SubStr($data,7,InStr($data,Chr(10))-7)
Else
$users=SubStr($data,1,InStr($data,Chr(10))-1)
EndIf
$x[$c]=$x[$c]+$users
If $my AND InStr($users,$logon)
$old[$c]=$x[$c]
EndIf
Next
$s=0
For $=0 to 7
If $x[$]<>$old[$]
$s=$x[$]
$hl.additem($x[$]+" "+Left(@time,5)+" on @mdayno. of "+Left(@month,3)+" {"+$forum[$]+"}",0)
$httpObj.Open("GET",$org+"ubb=forum&f="+$forumN[$]+"&DaysPrune=1&submit=Go")
$httpObj.send()
While $httpObj.readystate<>4 $nul=Execute($m.doevents(1)) Sleep 0.02 Loop
$data=$httpObj.Responsetext
$data=SubStr($data,InStr($data,$y[$]))
$nul=SubStr($data,"</td>")
If InStr($nul,'</a> <font face="Verdana, Helvetica, sans-serif" size="1"> Pages: <a')
$nul=SubStr($nul,InStrRev($nul,"</a>")-1,1)
Else
$nul=1
EndIf
$data=SubStr($data,InStr($data,"#f7f7f7"))
$data=SubStr($data,1,InStr($data,"</font>")-1)
$data=Val(SubStr($data,InStrRev($data,">")+1))
$hlurl.additem($y[$]+";p=$nul"+"#"+Right("00000$data",6),0)
EndIf
Next
EndIf
$old=$x
EndFunction

Function show($)
$m.height=$m.height+(100*$)
If $m.height=340
$hl.top=102
$hbh.top=275
$hbo.top=275
$hba.top=275
Else
$hl.top=2
$hbh.top=175
$hbo.top=175
$hba.top=175
EndIf
If $=2
$hl.show
$hbh.show
$hbo.show
$hba.show
Else
$bl.show
$blt.show
$bbh.show
$bbp.show
$bbr.show
$bbm.show
EndIf
$m.top=$screen-taskbar()+3-$m.height
$msg.top = $m.height-38
$fbe.top = $m.height-20
$fbh.top = $fbe.top
$fbb.top = $fbe.top
$fbs.top = $fbe.top
$m.show(1)
EndFunction

Function hide($)
$m.height=$m.height-(100*$)
If $=1
$fbb.enabled=1
$bl.hide
$bbh.hide
$bbp.hide
$bbr.hide
$bbm.hide
$blt.hide
Else
$fbh.enabled=1
$hl.hide
$hbh.hide
$hbo.hide
$hba.hide
EndIf
$m.top=$screen - (taskbar() + $m.height - 3)
$msg.top = $m.height-38
$fbe.top = $m.height-20
$fbh.top = $fbe.top
$fbb.top = $fbe.top
$fbs.top = $fbe.top
$hl.top=2
$hbo.top=175
$hba.top=175
$hbh.top=175
$m.show(1)
EndFunction

Function TaskBar()
If @dos=="4.0" $_S="StuckRects" Else $_S="StuckRects2" EndIf
$TaskBar=Val("&"+SubStr(ReadValue("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\$_S","settings"),41,2))
EndFunction

Function slide($sc,$scv)
Dim $t,$d,$l,$c,$p
$t = $screen - taskbar()
$d = 1
$p = CreateObject("Kixtart.Form")
$p.BorderStyle = 0
$p.Height = 22
$p.Width = 300
$p.fontsize = 10
$p.fontname = "helvetica"
$p.forecolor = 0
$p.fontbold = 1
$p.BorderStyle = 1
$p.backcolor = $p.RGB(255,255,0)
$p.Top = $t
$p.Left = $m.screen.width-760
$p.ShowInTaskbar = 0
$l = $p.hyperlink("$sc",2,2,296,18)
$l.Backcolor = $p.RGB(255,255,0)
$l.value = $scv
$c = $p.Timer(20)
$c.OnTimer = "
If $$d=1
$$p.Top=$$p.Top-1
If $$p.top<($$t-40)
$$c.Interval=3000
$$d=0
EndIf
Else
If $$d=2
$$c.Interval=20
$$p.Top=$$p.Top + 1
If $$p.top>$$t
$$c.Enabled=0
$$p.Hide
EndIf
Else $$d=2
EndIf
EndIf
"
$p.Show
$p.TopMost = 1
While $p.Visible
$=Execute($p.DoEvents)
Loop
EndFunction

Function misc()
$f = CreateObject("kixtart.form")
$f.caption = "bbChecker II - Miscellaneous"
$f.clientwidth = 250
$f.clientheight = 330
$f.top = $screen/2-100
$f.Left = $f.screen.width-720
$f.fontbold=1
$f.fontname = "Bookman Old Style"
$f.printxy(20,10,"bbChecker II 1.1.2")
$f.fontbold=0
$f.printxy(20,30,"Based on:")
$f.printxy(20,45,"Kixtart 4.11 (wkix32.exe)")
$f.printxy(20,60,"KixForms GUI (KixForms.dll)")
$f.printxy(20,80,"Special thanks for helping me out")
$f.printxy(20,95,"and making things possible go to:")
$f.fontitalic=1
$f.printxy(20,110,"Ruud Van Velsen")
$f.printxy(20,125,"Shawn Tassie")
$f.printxy(20,140,"Chris S. ,Patrick Rutten ...")
$f.printxy(20,155,"everyone contributing to kixtart.org bbs")
$f.fontitalic=0
$f.fontname = "helvetica"
$fp = $f.checkbox("Don't show my posts",20,235,130,15)
$f.printxy(150,220,"Logonname:")
$fpt = $f.textbox($logon,150,235,65,17)
$lt=$f.combobox(,150,258,40,17)
For $=10 to 99 $lt.additem($) Next $lt.value=$looptime
$f.printxy(20,260,"Post check interval (secs):")
$fo = $f.checkbox("Beep on post",20,280,110,15)
$fs = $f.checkbox("Show slider",20,300,90,15)
$fp.value = $my
If $fp.value $fpt.show Else $fpt.hide EndIf
$fo.value = $Beep
$fs.value = $sslider
$fb = $f.button("OK",170,305,75,20)
$fb.onclick = '$$f.hide'
$f.show
While $f.visible Sleep 0.02
$=Execute($f.doevents(1))
If $fp.value $fpt.show Else $fpt.hide EndIf
If 99<Val($lt.value) OR 10>Val($lt.value) $lt.value=$looptime EndIf
Loop
$looptime = Val($lt.value)
$Beep = $fo.value
$sslider = $fs.value
$my = $fp.value
$logon=$fpt.text
$=WriteValue($bk,"looptime",""+$looptime,"reg_sz")
$=WriteValue($bk,"beep",""+$Beep,"reg_sz")
$=WriteValue($bk,"slider",""+$sslider,"reg_sz")
$=WriteValue($bk,"my",""+$my,"reg_sz")
$=WriteValue($bk,"logon",""+$logon,"reg_sz")
$Loop.interval=1000*$looptime
EndFunction

:init
$m = CreateObject("kixtart.form")
Global $x[7]
$forum=Split("Starters Scripts General COM UDF Beta Suggestions FAQ")
$forumN=1,2,14,13,12,3,4,10
$old=$x $y=$x
$screen=$m.screen.height
$runie = "run '"+ReadValue("HKEY_CLASSES_ROOT\htmlfile\shell\open\command","")+" "
$org="http://www.kixtart.org/cgi-bin/ultimatebb.cgi?"
$m.caption = "BBChecker II"
$m.icon=@scriptdir+"\bb.ico"
$m.width = 430
$m.height = 40
$m.Left = $m.screen.width - $m.width - 20
$m.borderstyle = 0
$m.fontsize = 8
$m.fontname = "helvetica"
$m.forecolor = 0
$m.fontbold = 0
$msg = $m.hyperlink("Loading elements...",15,2,410,15)
$m.top = $screen - (taskbar() + $m.height - 3)
$fbe = $m.button("Exit",2,20,65,19)
$fbe.onclick = "$$m.visible = 0"
$fbs = $m.button("Miscellaneous",69,20,80,19)
$fbs.onmouseup = "$$m.show(2) misc() $$m.show"
$fbh = $m.button("History",$m.width - 68,20,65,19)
$fbh.enabled=0
$fbh.onclick = "$$fbh.enabled=0 show(2)"
$fbb = $m.button("Buddies",$fbh.Left - 68,20,65,19)
$fbb.enabled=0
$fbb.onclick = "$$fbb.enabled=0 show(1)"
$m.visible = 1

;history block
$hl = $m.listbox(0,2,2,426,170)
$hl.visible = 0
$hl.OnDblClick = "$$m.show(2) $$hlurl.listindex=$$hl.listindex $runie "+Chr(34)+"'+$$hlurl.text+'"+Chr(34)+"'"
$hl.mousepointer=16
$hbh = $m.button("Hide",$m.width - 80,175,75,20)
$hbh.visible = 0
$hbh.onclick = "hide(2)"
$hbo = $m.button("Show Topic",5,175,75,20)
$hbo.visible = 0
$hbo.onclick = "$$m.show(2) $$hlurl.listindex=$$hl.listindex $runie "+Chr(34)+"'+$$hlurl.text+'"+Chr(34)+"'"
$hba = $m.button("Today's Active topics",150,175,130,20)
$hba.visible = 0
$hba.onclick = "$$m.show(2) $runie "+Chr(34)+$org+"ubb=get_daily"+Chr(34)+"'"
$hlurl = $m.listbox(0,0,0,0,20)
$hlurl.visible = 0

;buddies block
$bl = $m.listbox(0,2,15,200,80)
$bl.visible = 0
$bll = $m.listbox(0,0,0,0,20)
$bll.visible = 0
$blt = $m.label("Logged on users:",5,2,150,12)
$blt.visible = 0
$bbh = $m.button("Hide",$m.width - 80,15,75,20)
$bbh.visible = 0
$bbh.onclick = "hide(1)"
$bbp = $m.button("Show Profile",210,15,78,20)
$bbp.visible = 0
$bbp.onclick = "$$m.show(2) $$bll.listindex=$$bl.listindex $runie "+Chr(34)+$org+"ubb=get_profile;u='+$$bll.text+'"+Chr(34)+"'"
$bbr = $m.button("Recent Posts",210,40,78,20)
$bbr.visible = 0
$bbr.onclick = "$$m.show(2) $$bll.listindex=$$bl.listindex $runie "+Chr(34)+$org+"ubb=recent_user_posts;u='+$$bll.text+'"+Chr(34)+"'"
$bbm = $m.button("Send Message",210,65,78,20)
$bbm.visible = 0
$bbm.onclick = "$$m.show(2) $$bll.listindex=$$bl.listindex $runie "+Chr(34)+$org+"ubb=private_message;u='+$$bll.text+'"+Chr(34)+"'"

;settings
$bk="HKEY_CURRENT_USER\Software\Jooel\bbChecker"
If NOT KeyExist($bk)
$=MessageBox("bbChecker II installation corruption!@crlfThis propably is due to unclean installation@crlfRe-install needed","bbChecker II",16)
Exit 0
EndIf
$looptime=Val(ReadValue($bk,"looptime"))
$Beep=Val(ReadValue($bk,"beep"))
$sslider=Val(ReadValue($bk,"slider"))
$my=Val(ReadValue($bk,"my"))
$logon=ReadValue($bk,"logon")

;xmlhttp related func
$xK="HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
$cache=ReadValue($xK,"SyncMode5")
$=WriteValue($xK,"SyncMode5","3","reg_dword")
$httpObj = CreateObject("microsoft.xmlhttp")

;at some point might want to have one instance for every forum for speed...
;global $forumIE[7]
;for $=0 to 7 $forumIE[$]=CreateObject("microsoft.xmlhttp") next

;finalize starting
parse()
$hl.clear
$hlurl.clear
$hl.additem("started at @time @date")
$hlurl.additem($org)
$hl.listindex=0
$bl.listindex=0
$s=0
$fbb.enabled=1
$fbh.enabled=1
$msg.caption = ""
$msg.value=""
$Loop = $m.timer(1000*$looptime)
$Loop.ontimer="update()"
Return

:final
$=WriteValue($xK,"SyncMode5",$cache,"reg_dword")
Return



[ 18. September 2002, 09:57: Message edited by: MightyR1 ]


MightyR1
(MM club member)
2002-09-18 09:59 AM
Re: devel of new checker

Added another reply to see if the jump is correct.

LonkeroAdministrator
(KiX Master Guru)
2002-09-18 10:01 AM
Re: devel of new checker

sadly no one is posting....

so, I decided to spam [Big Grin]


MightyR1
(MM club member)
2002-09-18 10:03 AM
Re: devel of new checker

I think it's working [Smile]

checking what happens if the topic is already in an IE window...


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 10:05 AM
Re: devel of new checker

it still seems to fail on me...
am I using wrong version or something...


MightyR1
(MM club member)
2002-09-18 10:05 AM
Re: devel of new checker

Nope it didn't.

Checking if IE has another page loaded (not KiX BB)


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 10:09 AM
Re: devel of new checker

for me it did work.

as long as the the address field is not the same last post on that topic.


MightyR1
(MM club member)
2002-09-18 10:34 AM
Re: devel of new checker

Found something else,

if you dblclick in the list box, a new browser window is opened. Clicking on the URL loads the page in an existing window...


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 10:38 AM
Re: devel of new checker

this has been allways there.
before shawn made his hyperlink, it did always open new window.

the thing that I'm worried about is that the execution of the main form hangs during the slider as before.
that was one major reason to keep it out of the checker file.
dunno, will probably take it out again and make ppl change to build their own sliders.

also, taking the parser part of the main script and calling it would ease up the upgrade when bbs changes...


MightyR1
(MM club member)
2002-09-18 10:45 AM
Re: devel of new checker

The open in new browser thingy was there all the time? Well then forget I mentioned it...

I changed the appearance of the slider already..
If the hang problem is solved by making a slider.kix again, just do it (no connection here with NIKE). You've got my permission... [Big Grin]


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 12:30 AM
Re: devel of new checker

uploaded the current files.
parse.udf and slider.kix are the changes


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 01:06 PM
Re: devel of new checker

going for coffee... you could check the new one...

does not quite work perfectly but if you check the code, you see that it supports already separate forums...

could do a nice memory load...


MightyR1
(MM club member)
2002-09-18 01:35 PM
Re: devel of new checker

Jooel,

check out this checker...
The DOS box display "slider.top slider.bottom slider.height". Can you explain the jump from 2 to 27 at the beginning?

Does your checker take more time to load the elements too???

code:
Break on
$d = 1
$h = 22
$h1 = 18
$w = 300
$p = CreateObject("Kixtart.Form")
$q = $p.screen.width
$p.BorderStyle = 0
$p.height = 0
$p.width = $w + 6
$p.fontsize = 10
$p.fontname = "helvetica"
$p.forecolor = 0
$p.fontbold = 1
$p.BorderStyle = 1
$p.backcolor = $p.RGB(255,255,0)
$p.Top = $t
$p.Left = $q-$p.width
$p.ShowInTaskbar = 0
$poplabel = $p.label($sc,2,$h1,$w,$h1)
$poplabel.backcolor = $p.rgb(255,255,0)
$poplabel.borderstyle = 0
$poplabel.alignment = 2
$p.onmousemove="$$poplabel.fontbold=1 $$poplabel.fontunderline=0"
$poplabel.onmousemove="$$poplabel.fontbold=1 $$poplabel.fontunderline=1"
$poplabel.onmouseup="$runie "+Chr(34)+$scv+Chr(34)+"' sleep 0.5 $$p.visible=0 "
$c = $p.Timer(20)
$c.OnTimer = "
If $$d=1
$$p.Top=$$p.Top - 1
$$p.height=$$p.Height+1
If $$p.top<($$t-3*$h1)
$$c.Interval=3000
$$d=0
EndIf
Else
If $$d=2
$$c.Interval=20
$$p.Top=$$p.Top + 1
$$p.height=$$p.Height-1
If $$p.top>$$t
$$c.Enabled=0
$$p.Hide
EndIf
Else $$d=2
EndIf
EndIf
"
$p.Show
$p.TopMost = 1
While $p.Visible
$=Execute($p.DoEvents)
Loop



[ 18. September 2002, 13:49: Message edited by: MightyR1 ]


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 01:37 PM
Re: devel of new checker

it takes up, about 10 times more time to load...

can fix that as soon as get my button change made.


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 01:45 PM
Re: devel of new checker

actually, don't know where you get that dos box as for me the slider just errored out [Big Grin]

anyway, tried to change that on new build...

it has it's own problems but anyway, will try to get it run nicely...


MightyR1
(MM club member)
2002-09-18 01:47 PM
Re: devel of new checker

Found the solution/problem myself...

it has something to do with the borderstyle. Changing the $p.BorderStyle to 0 gets rid of the jump from height 2 to 27 in the beginning.

It still doesn't explain the Jump!!

Shawn????


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 01:54 PM
Re: devel of new checker

ok, if you take bbchecker and parser...

most of the stuff should be fixed.

most importantly the boot time is really short.


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 01:56 PM
Re: devel of new checker

what jump you are talking about?

having the border ofcourse makes the height relations different...


MightyR1
(MM club member)
2002-09-18 02:07 PM
Re: devel of new checker

If you change the slider code to:
code:
;...
$c.OnTimer = "
? $$p.top ' ' $$p.bottom ' ' $$p.height sleep 0.2
If $$d=1
;...

the dos box gives:
code:
969 971 2
968 995 27
967 995 28

Notice the change (jump) in the .bottom (height) of 25.

I increment the height by 1!!!


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 02:10 PM
Re: devel of new checker

what about showintaskbar?

it actually does something weird and has done as far as I know.

you know, I make the slider to start from top of the taskbar and end when it gets above it.

well, it increases about 20-40 pixels too much...

[ 18. September 2002, 14:12: Message edited by: Lonkero ]


MightyR1
(MM club member)
2002-09-18 02:14 PM
Re: devel of new checker

I'm getting dizzy now...

Going home. Maybe try later this evening.


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 02:18 PM
Re: devel of new checker

ok, current build (1.2.8) seems to work as well as did 1.1.1 and it is fully ready for by forum lists...

maybe should move the show todays topics...

to keep the form height in reasonable limits...


ShawnAdministrator
(KiX Supporter)
2002-09-18 02:25 PM
Re: devel of new checker

Hey guys,

Im @ work right now and can't run BBChecker here (never could [Frown] ) anyways ... whazaby with this ... can anyone reproduce this with a little test script ? Its kinda tough to track these things down with a big script that has dependencies, etc ... you know what I mean.


LonkeroAdministrator
(KiX Master Guru)
2002-09-18 02:30 PM
Re: devel of new checker

oh boy...
well, as it's only slider, it's not big script...
wait a sec...
code:
	$t = $p.screen.height-taskbar()
$d = 1
$p = CreateObject("Kixtart.Form")
$p.BorderStyle = 0
$p.Height = 22
$p.Width = 300
$p.fontsize = 10
$p.fontname = "helvetica"
$p.forecolor = 0
$p.fontbold = 1
$p.BorderStyle = 1
$p.backcolor = $p.RGB(255,255,0)
$p.Top = $t
$p.Left = $p.screen.width-760
$p.ShowInTaskbar = 0
$l = $p.hyperlink("$sc",2,2,296,18)
$l.Backcolor = $p.RGB(255,255,0)
$l.value = $scv
$c = $p.Timer(20)
$c.OnTimer = "
If $$d=1
$$p.Top=$$p.Top-1
If $$p.top<($$t-40)
$$c.Interval=3000
$$d=0
EndIf
Else
if $$d=2
$$c.Interval=20
$$p.Top=$$p.Top + 1
If $$p.top>$$t
$$c.Enabled=0
$$p.Hide
EndIf
else $$d=2
endif
EndIf
"
$p.Show
$p.TopMost = 1
While $p.Visible
$=Execute($p.DoEvents)
Loop
exit 0

Function TaskBar()
If @dos=="4.0" $_S="StuckRects" Else $_S="StuckRects2" EndIf
$TaskBar=Val("&"+SubStr(ReadValue("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\$_S","settings"),41,2))
EndFunction



MightyR1
(MM club member)
2002-09-18 11:40 PM
Re: devel of new checker

Shawn,

did something change in the Borderstyle thingie?

On the KixForms site the latest news mentions a revised Borderstyle...

Is it possible to add a value for the form which makes the form appear with no titlebar and a 1-pixel border???


ShawnAdministrator
(KiX Supporter)
2002-09-19 12:06 AM
Re: devel of new checker

hmmm - yeah - just did a quick code chnage to forms and was able to achieve a "borderless" form (no title bar or windows borders) but has a thin one pixel "line" around all for corners - very nice ... how we going to integrate that into the interface though - vb,vba and .net don't have a property for that (i think) - mostly it would be custom draw stuff.

ShawnAdministrator
(KiX Supporter)
2002-09-19 12:52 AM
Re: devel of new checker

Guess we could just default the borderless form to that (thinline) ... hmmm ... then maybe implement the BorderColor property - and if we wanted to "hide" the thinline border, say this (?):

$Form.BorderStyle = 0
$Form.BorderColor = $Form.BackColor

guess the problem is that BorderStyle = 0 sort of implies that there is no border - thin, thick or otherwise - hmmm ...


MightyR1
(MM club member)
2002-09-19 12:59 AM
Re: devel of new checker

Shawn,

So the values for the form.borderstyle are equal to vb etc, am I right?

What about the other.borderstyles?

the other.borderstyle has a value (1) for 1-pixel border...


MightyR1
(MM club member)
2002-09-19 01:02 AM
Re: devel of new checker

Jooel,

does your slider steal focus??? Mine does...

Isn't the only workaround putting the slider back in the checker? AAARRGHH [Mad]


ShawnAdministrator
(KiX Supporter)
2002-09-19 01:07 AM
Re: devel of new checker

I tried to make BorderStyle identical with VB's version ... but "extended" it for controls to support those funky "sunken", "raised" and "framed" styles. Yeah - BorderStyle for Forms and for Controls has different meanings ... just like in VB. One can't specify a "sunken" form.

MightyR1
(MM club member)
2002-09-19 01:10 AM
Re: devel of new checker

Shawn,

Thnx for making it clear.

For now i just use borderstyle=0 for the form and 1 for a label which I put over the form (same size)...


ShawnAdministrator
(KiX Supporter)
2002-09-19 01:23 AM
Re: devel of new checker

Is your form going to change size at all ? Are you going to putting controls on your form ?

MightyR1
(MM club member)
2002-09-19 01:30 AM
Re: devel of new checker

I'm playing around with a slider for myself:

code:
Break on 

$runie = "run '"+ReadValue("HKEY_CLASSES_ROOT\htmlfile\shell\open\command","")+" "

$d = 1
$h = 22
$h1 = 18
$w = 300
;$t=700
$p = CreateObject("Kixtart.Form")
$p.height = 0
$p.width = $w + 6
$p.fontsize = 10
$p.fontname = "helvetica"
$p.forecolor = 0
$p.fontbold = 0
$p.BorderStyle = 0
$p.backcolor = $p.RGB(255,255,0)
$p.Top = $t
$p.Left = $p.screen.width-$p.width-20
$p.minbutton=0
$p.maxbutton=0

;$q = $p.label("",0,0,$p.width,3*$h1+3)
;$q.backcolor=$p.rgb(255,255,0)
;$q.borderstyle=1
$poplabel = $p.label($sc,4,2+$h1/2,$w-2,2*$h1)
$poplabel.backcolor = $p.rgb(255,255,0)
$poplabel.borderstyle = 0
$poplabel.alignment = 2
$p.onmousemove="$$poplabel.fontbold=0 $$poplabel.fontunderline=0"
$poplabel.onmousemove="$$poplabel.fontbold=0 $$poplabel.fontunderline=1"
$poplabel.onmouseup="$runie "+Chr(34)+$scv+Chr(34)+"' sleep 0.5 $$p.visible=0 "

$c = $p.Timer(20)
$c.OnTimer = "
If $$d=1
$$p.Top=$$p.Top - 1
$$p.height=$$p.Height+1
If $$p.top<($$t-3*$h1)
$$c.Interval=3000
$$d=0
EndIf
Else
If $$d=2
$$c.Interval=20
$$p.Top=$$p.Top + 1
$$p.height=$$p.Height-1
If $$p.top>$$t
$$c.Enabled=0
$$p.Hide
EndIf
Else
$$d=2
EndIf
EndIf
"
$p.height=0
$p.ShowInTaskbar = NOT 1
$p.Show
$p.ShowInTaskbar = NOT 1
$p.TopMost = 1

While $p.Visible
$=Execute($p.DoEvents)
Loop

If I enable the q label, I can't click the link in the slider...

- - Me is missing something - -


ShawnAdministrator
(KiX Supporter)
2002-09-19 01:36 AM
Re: devel of new checker

Why don't you just draw a thin border around the inside of the form using the LINE method ? Chris's original POPUP.KIX script has the algorithm for doing that.

LonkeroAdministrator
(KiX Master Guru)
2002-09-19 06:53 AM
Re: devel of new checker

so, shawn....
quess once what I want?

a slider, or popup object that does not require creating another form.

I've noticed the same as patrick, if I put the slider to run simultaneously, the form does not hang but it steels focus.

if I then put the slider into the main process, it does not steal focus but it hangs the main form. [Confused]
 


Kdyer
(KiX Supporter)
2002-09-19 06:58 AM
Re: devel of new checker

Jooel,

Question..

With this newer version, at home I see colored hyperlinks.. At work, all black text.

Why is that?

Kent


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 07:11 AM
Re: devel of new checker

well, only thing I can think of that you don't have kixforms 2.0.5 properly installed.

the hyperlinks come from there and their colors.

also, you may still have at home the older checker which had my own made hyperlinks... the 2.0 or something.
those were just black test, which behaved like hyperlinks... you know, catching the events onmouseover and onclick...


ShawnAdministrator
(KiX Supporter)
2002-09-19 07:28 AM
Re: devel of new checker

HyperLink pulls its default color settings from here:

HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Settings

Wha u got 4 that ?

-Shawn


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 08:01 AM
Re: devel of new checker

shawn, shouldn't you be in bed or something?

anyway, patrick, the parser does not function correctly for the page stuff...

will fix it tonight. will also include the slider back to the main process but will keep it out of the script file... just call it makes it easier to update... you know, just the peace...

 


Kdyer
(KiX Supporter)
2002-09-19 08:06 AM
Re: devel of new checker

Shawn,

quote:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Settings]
"Anchor Color Visited"="128,0,128"
"Anchor Color"="0,0,255"
"Background Color"="192,192,192"
"Text Color"="0,0,0"
"Use Anchor Hover Color"="No"

HTH,

Kent


NTDOCAdministrator
(KiX Master)
2002-09-19 08:36 AM
Re: devel of new checker

[HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Settings]
"Anchor Color Visited"="128,0,128"
"Anchor Color"="0,0,255"
"Background Color"="192,192,192"
"Text Color"="0,0,0"
"Use Anchor Hover Color"="No"


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 09:37 AM
Re: devel of new checker

the new parse.udf correctly gets to the post.
meaning that if you choose a post from a topic that is 9 pages long and the post is on the fifth page in the middle, the parser makes the link to go there...

so, no more searches if you have checker running...
if we just could get the memory consumption lower...

shawn, if I release the timer and re-create it, does that free up the mem?


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 10:14 AM
Re: devel of new checker

ok, to get it to really work as stand-alone parser and make it easier for ppl to upgrade it on forum update... introduction of new forum is pretty messy thing, but introducing new version of bb-software is only handled by parser...

basically, what I'm about to do and after is to split the parser code into:
parse() - only the info on the updates. outputs array of updates
update() - if update, pulls them to the appwindow and listboxes...


ShawnAdministrator
(KiX Supporter)
2002-09-19 02:46 PM
Re: devel of new checker

Jooel - heres the lowdown on the Timer thingy:

First off, in general, we have to remember that Kixtart is an interpreted scripting language, not a compiler (I know you know this - just making a point). And as such, has a certain latency in terms of responding to the real live windows events. Add to that the overhead associated with COM Automation and you can maybe see where I'm "heading" here.

In some of my very early performance test (with the KIXBGI32 component and later on with Kixforms 1.0) I discovered that with a reasonably fast machine (500mhz) - the "minimum" elapsed time to invoke a COM call is roughly about 1 or 2 ms. Then add to that some script processing and the times I've seen can jump to roughly 10 ms or so (like if you inside a small WHILE loop making COM calls).

Anyways - what happens is that when the Timer object is running - it is continously generating windows timer events (say every 10ms or so). And its up to you (us) to "handle" these events in the script (by invoking DoEvents). Well - if your event handler takes longer than 10ms to run - what happens is that there is a backlog of timer events in the queue ... maybe backlog is a bad word ... a series of "missed" timer events can occur.

If you already have an event "waiting" in the queue - and another timer event arrives (because your script is too slow to empty the queue), windows just discards the event in the queue and replaces it with the new one. But - inside that discarded event is the "event string" that we specified in the $Timer.OnTimer property. Windows doesn't destroy that string, so i have to make a change to Forms to handle this situation. And this situation arises only with the timer event - not true for all the other events. I went to great pains to insure that all events in Kixforms are trapped and handled (as you found out with your BBChecker Buddies and History buttons, all clicks are captured!).

Actually - its not a tough change to make but i got my head wrapped-up in ListViews right now. Suspect that improved timers will make their appearance in 2.1.1 or so.

-Shawn

[ 19. September 2002, 14:47: Message edited by: Shawn ]


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 02:58 PM
Re: devel of new checker

huh, long text!

so, what comes to the "event queue", it is hard to think that the form timer is causing this as it is timed on my test script to 60secs.

well, the slider is definitely another thing.

we can surely fix this in the script, I even had a workaround for the slider but forgot what it was...

anyway, thanks for being a rock solid on this issue too [Big Grin]
 


ShawnAdministrator
(KiX Supporter)
2002-09-19 03:17 PM
Re: devel of new checker

Yeah - the 60sec timer shouldn't be leaking - the slider timer probably leaks ... but how often does the slider slide (only when a new post arrives right?) ... Unfortunately - I haven't had the time lately to delve much into the current version of BBChecker and maybe see whats going on. But I imagine (without looking at the code) that if you leave the Slider timer running (forget to turn it off after the slide) that it will chew up memory pretty quick. If (my) memory serves - the Slider was running at 10ms or so. The way to turn a timer off is with:

$Timer.Interval = 0

or

$Timer.Enabled = 0

so maybe you should disable the Timer when its first created, then enable the timer when slider is first called, then disable the timer again before you leave the function. (maybe your already doing that?)

[ 19. September 2002, 15:17: Message edited by: Shawn ]


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 03:20 PM
Re: devel of new checker

no, as the slider is own instance of the form-object.

the timer gets disabled yep...
$$c.Enabled=0

but it is deleted and re-created every time slider runs as is the form too.


Chris S.
(MM club member)
2002-09-19 04:18 PM
Re: devel of new checker

Jooel said:

quote:

if I then put the slider into the main process, it does not steal focus but it hangs the main form.

Are you creating the slider form from within the slider() function? If so, remember to destroy it before exiting the function. When I was working on integrating my slider into your script I found that if I didn't I got all sorts of problems.


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 04:19 PM
Re: devel of new checker

patrick, I also found that thing with not opening the last post if in the same page of same topic.

well, does not hurt so much.

I also got the slider to break the checker totally [Big Grin]

after it slides back, the checker will start show and hide in amazing speed! [Eek!]

I would show you but do not have video camera here...

anyways, other good thing, making sliders borderstyle is weird as you can move it up and watch it sliding down, catch it pull back up and watch again... [Big Grin]

roflol... should I go to bed or something...


MightyR1
(MM club member)
2002-09-19 05:34 PM
Re: devel of new checker

Shawn,

thnx for the LINE tip, will try with new checker...


ShawnAdministrator
(KiX Supporter)
2002-09-19 05:41 PM
Re: devel of new checker

Hats off to you if you get it to work - the challenge with framing the Checker is that you will (probably) have to erase background (clear) the form and redraw the border every time the checker gets resized by the the user (which is often) ... I will be implementing OnResize in a future release. Might want to check out that KixMessenger script as well - it also draws a couple of borders around the inside of the form (also uses variable width lines) but have never seen a dynamic border draw done yet. [Wink]

LonkeroAdministrator
(KiX Master Guru)
2002-09-19 06:42 PM
Re: devel of new checker

Hey all...
again.

especially patrick, check the NEW 1.3 beta 1!

woah, got it to work after all...
what ya think?
 


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 09:59 PM
Re: devel of new checker

btw,
a word of warning:
the slider might be interfering with main form...

just may, I tried to fix it in this latest build but can't be sure...


MightyR1
(MM club member)
2002-09-19 10:22 PM
Re: devel of new checker

Jooel,

really fantastic. Can't say anymore... [Big Grin] [Big Grin]

Is there a way to reproduce the little bug??? Else maybe this can be a new release??


ShawnAdministrator
(KiX Supporter)
2002-09-19 10:26 PM
Re: devel of new checker

Got to hand it to you Jooel [guys] - this BBChecker script is incredible ... what else can I say ?

-Shawn


LonkeroAdministrator
(KiX Master Guru)
2002-09-19 10:37 PM
Re: devel of new checker

well patrick, let it roll for a while.

I didn't change the parser yet as it would change this pretty much...

maybe next release.
if you get any errors, we shall fix them.
if you don't we have to wait few seconds longer [Big Grin]

shawn got me thinking on the slider addon...
what about a slider or visibility changer script?
script that changes the appearance of the form and the slider...

shawn, I think we are after just something amazing and it's nice to hear that this is getting good... after all.


MightyR1
(MM club member)
2002-09-20 12:04 AM
Re: devel of new checker

Shawn

is this what you where looking for???
If so, let us see you take your hat off [Big Grin]

code:
Function slide($sc,$scv)
Dim $t,$d,$p,$l,$c,$h,$w,$h1,$poplabel
$d = 1
$h = 22
$h1 = 18
$w = 300
$p = CreateObject("Kixtart.Form")
$p.height = 0
$t=$p.screen.height-75
$p.height = 0
$p.width = $w + 6
$p.fontsize = 10
$p.fontname = "helvetica"
$p.forecolor = 0
$p.fontbold = 0
$p.BorderStyle = 0
$p.backcolor = $p.RGB(255,255,0)
$p.Top = $t
$p.Left = ($p.screen.width-$p.width)/2

$poplabel = $p.label($sc,4,2+$h1/2,$w-2,2*$h1)
$poplabel.backcolor = $p.rgb(255,255,0)
$poplabel.borderstyle = 0
$poplabel.alignment = 2
$p.onmousemove="$$poplabel.fontbold=0 $$poplabel.fontunderline=0"
$poplabel.onmousemove="$$poplabel.fontbold=0 $$poplabel.fontunderline=1"
$poplabel.onmouseup="$runie "+Chr(34)+$scv+Chr(34)+"' sleep 0.5 $$p.visible=0 "

$c = $p.Timer(20)
$c.OnTimer = "
If $$d=1
$$p.Top=$$p.Top - 1
$$p.height=$$p.Height+1

$$ptopline=$$p.line(0,0,$$p.width,0)
$$pleftline=$$p.line(0,0,0,$$p.height)
$$prightline=$$p.line($$p.width-1,0,$$p.width-1,$$p.height)
$$p.forecolor=$$p.RGB(255,255,0)
$$pbottomline=$$p.line(1,$$p.height-2,$$p.width-1,$$p.height-2)
$$p.forecolor=0
$$pbottomline=$$p.line(0,$$p.height-1,$$p.width,$$p.height-1)

If $$p.top<($$t-3*$h1)
$$c.Interval=3000
$$d=0
EndIf
Else
If $$d=2
$$c.Interval=20
$$p.Top=$$p.Top + 1
$$p.height=$$p.Height-1

$$ptopline=$$p.line(0,0,$$p.width,0)
$$pleftline=$$p.line(0,0,0,$$p.height)
$$prightline=$$p.line($$p.width-1,0,$$p.width-1,$$p.height)
$$p.forecolor=$$p.RGB(255,255,0)
$$pbottomline=$$p.line(1,$$p.height-2,$$p.width-1,$$p.height-2)
$$p.forecolor=0
$$pbottomline=$$p.line(0,$$p.height-1,$$p.width,$$p.height-1)

If $$p.top>$$t
$$c.Enabled=0
$$p.Hide
EndIf
Else
$$d=2
EndIf
EndIf
"
$p.height=0
$p.Show
$p.ShowInTaskbar = 0
$p.TopMost = 1

While $p.Visible
$=Execute($p.DoEvents)
Loop

EndFunction

Jooel,

notice the $p.height=0 before the $p.show. It gets rid of the JUMP we discussed earlier...
Maybe you could use it in your slider.udf for the position of the slider.


ShawnAdministrator
(KiX Supporter)
2002-09-20 01:01 AM
Re: devel of new checker

 -

LonkeroAdministrator
(KiX Master Guru)
2002-09-20 06:58 AM
Re: devel of new checker

mmm...
at home still, but as I get to work, I'll even try that.

just now I have to wonder the p.height=0 which you put there triple...

ah so, btw...
I'm leaving on a "vacation" tomorrow morning.
will fly back to my seat on next friday evening.


MightyR1
(MM club member)
2002-09-20 07:31 AM
Re: devel of new checker

Shawn,

Nice.....

Jooel,

you're probably right, the first two can be removed. Talk about not cleaning your mess up after development...


LonkeroAdministrator
(KiX Master Guru)
2002-09-20 09:01 AM
Re: devel of new checker

shawn, I wonder, is locking the combobox possible?
you know, to make it real dropdown menu...

dunno, the misc has it locked as I did in the loop check for it to be a lecal value...

I'm not sure am I just blind or do I have to do the same for the main form?


LonkeroAdministrator
(KiX Master Guru)
2002-09-20 10:03 AM
Re: devel of new checker

just to be sure,
made a package:
http://www.gwspikval.com/jooel/scripts/bbChecker/BBCheckerII_1.3_RC-1.exe

don't think there is lot to improve for this version as if I do that, it will get to 1.5 really soon, so better to just drop it here.


MightyR1
(MM club member)
2002-09-20 11:42 AM
Re: devel of new checker

Jooel,

just got a "script error" when CYW posted Auto Check Name for Outlook Profile

the checker was running for about 3 hours...

Is this the "BUG"???


LonkeroAdministrator
(KiX Master Guru)
2002-09-20 11:51 AM
Re: devel of new checker

I got one also when started the checker and went to change the settings.

I have no idea where it comes from...

nice thing is that it does not say the error. it just says it got one.
[Frown] [Frown] [Frown] [Frown] [Frown]

anyway, instead of that, it seems to run just fine.

I leave it in background now and will be monitoring.
also, I might make a debugger version of the checker... or you even...
with the great kixstrip...
this way could catch the place it is crashing.

btw, check on the newist slider. it adjusts the place and width of itself depending on the width of the link.
this way no stupid left-over space at the end. what you think?


MightyR1
(MM club member)
2002-09-21 12:41 AM
Re: devel of new checker

AARRRGG,

error occurred again...

will test your new slider....


LonkeroAdministrator
(KiX Master Guru)
2002-09-21 12:45 AM
Re: devel of new checker

what is the versio of the checker you are using?

as I haven't got any errors after that one before...

strange.


MightyR1
(MM club member)
2002-09-20 01:46 PM
Re: devel of new checker

Jooel,

It's the checker with the label...

See a few posts earlier, just before Mr. "Shawn" Potato-head. (Shawn, just kidding here... [Wink] )


ShawnAdministrator
(KiX Supporter)
2002-09-20 01:56 PM
Re: devel of new checker

rofl

LonkeroAdministrator
(KiX Master Guru)
2002-09-20 02:13 PM
Re: devel of new checker

you mean slider?

I have no bad luck with my current build...

not at all.
think I'll make it a release as can't be building anymore due to vacation call.

heh, boss said: "you must take one week of!"
well, can't fight with him...

just need 2 weeks before next board update.
as then I'll make version of the checker that only needs parse.udf to make the code compatible with the new board versions...

now, I have to do some work as our nt-dns-servers are causing me pain.


MightyR1
(MM club member)
2002-09-20 02:16 PM
Re: devel of new checker

Duhhh,

yep the slider...my mistke...

PS found no other problems with the checker either.


LonkeroAdministrator
(KiX Master Guru)
2002-09-20 02:35 PM
Re: devel of new checker

pat, if you have the bbchecker.exe of the version 1.1.1 there, could you post it?

I mistakenly deleted it and would like have it in the archives.


MightyR1
(MM club member)
2002-09-20 02:46 PM
Re: devel of new checker

Think I have,

check your mail...


LonkeroAdministrator
(KiX Master Guru)
2002-09-20 02:53 PM
Re: devel of new checker

got it but outlook denies to give it to me...

MightyR1
(MM club member)
2002-09-20 02:58 PM
Re: devel of new checker

Will send you a new one, not exe....