drmcphatt
(Lurker)
2002-09-09 09:33 PM
Norton Script

I used the Vplogon.bat to install norton on my lan, but the GRC.dat file did not copy to all the pc's due to being in other locations.

Does anybody know of a kix script that will copy the grc.dat file to Windows 9x, NT, 2000 clients. I am thinking it will need to shell to find the grc.dat and then copy that grc.dat to the appropriate windows location. Any help would be very very helpful.

thanks.

Les
(KiX Master)
2002-09-09 10:59 PM
Re: Norton Script

Welcome to the board. Did you try searching the board for "GRC"? I'm sure you'd find a few excellent examples.

NTDOCAdministrator
(KiX Master)
2002-09-09 11:23 PM
Re: Norton Script

Or.. if a search does not turn one up, here is one you can work on and modify or gleen more information from.

code:
IF @INWIN = 1
	$SRVR = ReadValue("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ProductOptions", "ProductType")
	IF $SRVR<>"WinNT"	; System is not a Workstation so assume it is a Server
		RETURN
	ENDIF
ENDIF
IF $NoNavWarn <> 0
	$nul = MESSAGEBOX("Unable to locate the Norton AntiVirus program on this system.  Please contact the Helpdesk to have the program installed or checked for problems with a previous installation. ", "Norton AntiVirus Program Update", 16)
	RETURN
ENDIF

IF EXIST($NavHome+"\GRC.DAT")
	SHELL $CleanGRCx
	DEL ($NavHome+"\GRC.DAT")
ENDIF
IF EXIST("$DataLocation\Symantec\Norton AntiVirus Corporate Edition\7.5\GRC.DAT")
	SHELL $CleanGRCy
	DEL ("$DataLocation\Symantec\Norton AntiVirus Corporate Edition\7.5\GRC.DAT")
ENDIF

SELECT
	CASE (SUBSTR(@IPADDRESS1,1,7)) = "129.105" AND $PARENT = "server1"
		RETURN
	CASE (SUBSTR(@IPADDRESS0,1,7)) = "122.123" AND $PARENT = "server2"
		RETURN
	CASE (SUBSTR(@IPADDRESS0,1,7)) = "122.116" AND $PARENT = "server3"
		RETURN
ENDSELECT

SELECT
	CASE (SUBSTR(@IPADDRESS0,1,11)) = "129.105.122"
		$NavParent = "server1"
	CASE (SUBSTR(@IPADDRESS0,1,11)) = "122.123.121"
		$NavParent = "server2"
	CASE (SUBSTR(@IPADDRESS0,1,11)) = "122.116.122"
		$NavParent = "server3"
	CASE 1
		$NavParent = "server1"
ENDSELECT
$GrcUpdateNew = '%comspec% /c copy "\\$NavParent\vphome\grc.dat" "$DataLocation\Symantec\Norton AntiVirus Corporate Edition\7.5\GRC.DAT" >nul'
$GrcUpdateOld = '%comspec% /c copy "\\$NavParent\vphome\grc.dat" "$NavHome" >nul'

IF @INWIN = 1
	IF (Exist($DataLocation+"\Symantec\Norton AntiVirus Corporate Edition\7.5\nul") = 1)
		$x = MESSAGEBOX("Please wait... Norton AntiVirus Definitions are being updated on your system...", "Norton AntiVirus Program Update", 64, 10)
		SHELL $GrcUpdateNew
		SHELL '%comspec% /c NET STOP "Norton AntiVirus Client" >NUL'
		SHELL '%comspec% /c NET START "Norton AntiVirus Client" >NUL'
		RETURN
	ELSE
		$x = MESSAGEBOX("Please wait... Norton AntiVirus Definitions are being updated on your system...", "Norton AntiVirus Program Update", 64, 10)
		SHELL $GrcUpdateOld
		SHELL '%comspec% /c NET STOP "Norton AntiVirus Client" >NUL'
		SHELL '%comspec% /c NET START "Norton AntiVirus Client" >NUL'
		RETURN
	ENDIF
ENDIF

IF @INWIN = 2
	SHELL $GrcUpdateOld
	$x = MESSAGEBOX("Notice: Norton AntiVirus Definitions were updated on your system.  Please restart your computer to complete the Norton AntiVirus update once the logon script and any other applications have finished loading.", "Norton AntiVirus Program Update", 64)
	RETURN
ENDIF
RETURN

cmarti
(Hey THIS is FUN)
2002-09-10 06:28 PM
Re: Norton Script

Here's what I use to dump the grc.dat to the client, this is using kix 4.02 and nav 7.60. I determine the $NAVSVR variable in an earlier portion of my script depending on which segment the user is on.. L8tr...

code:
  
Select
  Case @PRODUCTTYPE = "Windows 2000 Professional" OR @PRODUCTTYPE = "Windows XP Professional"
    Copy "\\$NAVSVR\VPHOME\GRC.DAT" "%ALLUSERSPROFILE%\Application Data\Symantec\Norton AntiVirus Corporate Edition\7.5\GRC.DAT"
  Case @PRODUCTTYPE = "Windows NT Workstation"
    Copy "\\$NAVSVR\VPHOME\GRC.DAT" "C:\winnt\profiles\all users\application data\symantec\norton antivirus corporate edition\7.5\GRC.DAT"
  Case 1
    Copy "\\$NAVSVR\VPHOME\GRC.DAT" "C:\Program Files\Norton AntiVirus\grc.dat"
EndSelect

NTDOCAdministrator
(KiX Master)
2002-09-10 10:53 PM
Re: Norton Script

David,

Here is some more specific code that should work for you based on using KiXtart v3.6x

code:
$NAVHome = ReadValue("HKEY_LOCAL_MACHINE\software\INTEL\LANDesk\VirusProtect6\CurrentVersion\", "Home Directory")
$NavHomeDir = READVALUE("HKEY_LOCAL_MACHINE\SOFTWARE\INTEL\LANDesk\VirusProtect6\CurrentVersion","Home Directory")
$DataLocation = READVALUE("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders", "Common AppData")
$PARENT = READVALUE("HKEY_LOCAL_MACHINE\SOFTWARE\Intel\LANDesk\VirusProtect6\CurrentVersion","Parent")
$NavParent = "rsl"
$GrcUpdateNew = '%comspec% /c copy "\\$NavParent\vphome\grc.dat" "$DataLocation\Symantec\Norton AntiVirus Corporate Edition\7.5\GRC.DAT" >nul'
$GrcUpdateOld = '%comspec% /c copy "\\$NavParent\vphome\grc.dat" "$NavHome" >nul'

IF @INWIN = 1
	IF (Exist($DataLocation+"\Symantec\Norton AntiVirus Corporate Edition\7.5\nul") = 1)
		SHELL $GrcUpdateNew
		RETURN
	ELSE
		SHELL $GrcUpdateOld
		RETURN
	ENDIF
ENDIF

IF @INWIN = 2
	SHELL $GrcUpdateOld
	RETURN
ENDIF
RETURN


[ 12. September 2002, 01:19: Message edited by: NTDOC ]

NTDOCAdministrator
(KiX Master)
2002-09-12 01:20 AM
Re: Norton Script

David,

sorry, I left out this line for the Windows 9x systems. I have updated the code above to include it.

$NAVHome = ReadValue("HKEY_LOCAL_MACHINE\software\INTEL\LANDesk\VirusProtect6\CurrentVersion\", "Home Directory")