; This function scores the specified file and returns the KixGolf score.
; That is the total number of key strokes used to build a script not counting
; comments, spaces, tabs, or any ascii character above 126.
Function KixGolf($A)
if open (1,$A) = 0
$X=0
$Q=""
$C=readLine(1)
while @error=0
$j=len($C) ; Get length of the line
for $h=1 to $j ; Loop through each character in line
$D=asc(substr($C,$h,1))
if $D=34 or $D=39
if $Q=""
$Q=$D
else
if $Q=$D
$Q=""
endif
endif
endif

if $D=59 ; Ignore comment lines
$h=$j ; Terminate loop
else
if $Q<>""
$X=$X+1 ; Count the valid characters
else
if $D>32 and $D<127
$X=$X+1 ; Count the valid characters
endif
endif
endif
next
$C=readLine(1)
loop
else
? "$A ??" ; Show bad file name
endif
if $Q<>""
? "Mis-matched quotes. Probable score error." ?
endif
$KixGolf=$X
EndFunction

? "KixGolf score = " + KixGolf($A) ;$A must be initialized on the command line.
;%tmp%\kix32 kixgolf.kix $A=Kixgolf.kix

$Q = 0
$R = 0
$C = 0
if Open (1,$f) = 0
While @error=0
$L = READLINE(1)
$M = LEN($L)
For $I = 1 to $M
$A=asc(substr($L,$i,1))
IF $A = 34 AND $R = 0
$Q = $Q + 1 & 1
ENDIF
IF $A = 39 AND $Q = 0
$R = $R + 1 & 1
Endif
If $A = 59 $I = $M
Else
If $Q|$R
$C = $C + 1
Else
If $A > 32 AND $A < 127
$C = $C + 1
Endif
Endif
Endif
Next
Loop
$ = Close(1)
Else
"$F?" ?
Endif
If $Q|$R
"Mis-matched quotes. Probable score error." ?
Endif
"KixGolf score = " + $C

Howard,

Your KixGolf scoring script is reporting to few point !!!

Each CRLF must be counted as one point (nessesary whitespace)
Also it dosn't count the nessary whitespaces inside the code,
your script will count this code:

code:

If $a>5 $x=1 EndIf

As 15 points
Assuming this would be working KiX-code:

code:

If$a>5$x=1EndIf

The result should be 18, because all the whitespaces are required.

The following UDF, also counts required whitespaces, it might
stil need some minor ajusts.

I have added the possibility to count parts of a script.
If the optional parameter $CountMarkers is used and <> '' or 0 the UDF wil
look for the line:
;GolfStart
before beginning to count
And wil stop counting when the line:
;GolfEnd
is found.

code:

Function KixGolf($A,Optional $CountMarkers)
  $SpaceChars=Chr(9)+' ,;=<>()+-*/"'+"'"
  If Open(1,$A) = 0
    $X=0
    If $CountMarkers
      Do
        $C=ReadLine(1)
      Until $C = ';GolfStart'
    EndIf
    $C=ReadLine(1)
    While @Error=0 And $C <> ';GolfEnd'
      $InStr = 0
      $StrCh = ''
      $j=len($C)
      For $h=1 To $j
        $Ch = substr($C,$h,1)
        If $Ch = '"' Or $Ch = "'"
          If $InStr
            If $Ch = $StrCh
              $InStr = 0
            EndIf
          Else
            $InStr = 1
            $StrCh = $Ch
          EndIf
          $X=$X+1               ; Count stringdelimiter
        Else
          If $InStr
            $X=$X+1             ; Count all chars inside strings
          Else
            $D=Asc($Ch)
            If $D=59            ; Ignore comments in rest of line
              $h=$j
            Else
              If $D=9 Or $D=32  ; Space or Tab: Count only if whitespace is demanded
                $Count = 1
                If InStr($SpaceChars,SubStr($C,$h-1,1))
                  $Count=0
                Else
                  If InStr($SpaceChars,SubStr($C,$h+1,1))
                    $Count=0
                  EndIf
                EndIf
                $X=$X+$Count
              Else
                $X=$X+1         ; Count the character
              EndIf
            EndIf
          EndIf
        EndIf
      Next
      $C=Trim(ReadLine(1))
      If $C <> '' And Left(Trim($C),1) <> ';'
        $X=$X+1                ; Each CRLF counts as one whitespace, If not a full comment-line
      EndIf
    Loop
    $RC=Close(1)
    $KixGolf=$X
  Else
    $KixGolf = "KixGolf, bad filename: " + $A
  EndIf
EndFunction

-Erik

ps.
I belive that only expirienced 'KiXters' will use this function, so it is not commented
on how to use.
I won't release it in the UDF section because i am sure it can be improved, and maybe
some of you wil have something to add.
Also, this UDF is of no general use, so maybe this or something similar should be linked
directly to the active Golf tournament.

[ 17 July 2002, 22:19: Message edited by: kholm ]