; KIXTART 4.01

break on cls
color w/n
srnd(@msecs)
$t=5

$greenies = 15
$greenie = marray("$greenies,2")
for $i=0 to $greenies
 $greenie[$i][0] = rnd(24)
 $greenie[$i][1] = rnd(78)
next

$blankies = 15
$blankie = marray("$blankies,2")
for $i=0 to ubound($blankie)
 $blankie[$i][0] = rnd(24)
 $blankie[$i][1] = rnd(78)
next

$=setoption("hidecursor","on")

while not kbhit()
 for $i = 0 to $greenies
  color g/n
  $c=rnd(100)+100
  if $c=7 or $c=149
   $c=150
  endif
  if $greenie[$i][0]
   at($greenie[$i][0],$greenie[$i][1]) chr($c)
  endif
  if $greenie[$i][0] < 23
   $greenie[$i][0] = $greenie[$i][0] + 1
   color g+/n
   at($greenie[$i][0],$greenie[$i][1]) chr($c)
  else 
   $greenie[$i][0] = rnd(5)
   $greenie[$i][1] = rnd(78)
  endif
  delay($t)
 next
 for $i = 0 to $blankies
  color w/n
  at($blankie[$i][0],$blankie[$i][1]) " "
  $blankie[$i][0]=$blankie[$i][0]+1
  if $blankie[$i][0] = 24
   $blankie[$i][0]=0
   $blankie[$i][1]=rnd(78)
  endif
  delay($t)
 next
 color w/n
 delay($t)
loop
get$
 
cls
exit 1

function delay($n)
 $ticks = @ticks +$n
 while @ticks < $ticks
 loop
endfunction

function marray($ind, optional $ptr)
if ubound($ind)
else 
 $ind = split($ind,",") 
endif
redim $marray[$ind[$ptr]]
if $ptr < ubound($ind)
 $marray[0] = marray($ind,$ptr+1)
 dim $L
 for $l = 1 to ubound($marray)
  $marray[$L]=$marray[0] 
 next
endif
endfunction


; KIXTART 4.01

break on cls

color w/n

srnd(@msecs)

$t=15

while not kbhit()
 $row = rnd(23)
 $col = rnd(78)
 if rnd(4) = 2
  for $i = 0 to 24
   at($i,$col) " "
   delay($t)
  next
 else  
  for $i = 0 to $row
   $c = rnd(100)+100
   if $c<>7 and $c<>149
    color g+/n
    at($i,$col) chr($c)
    if $i
     color g/n
     at($i-1,$col) chr($c)
    endif
    color w/n
    delay($t)
   endif
  next
 endif
 delay($t)
loop
get$
 
cls
exit 1

function delay($n)
 $ticks = @ticks +$n
 while @ticks < $ticks
 loop
endfunction

[ 17 December 2001: Message edited by: Shawn ]